Simon: Trò chơi hoàn chỉnh

// Mỗi màu có một phần tử: đỏ, xanh lá, xanh dương, vàng
const int ledPins[4] = {9, 10, 11, 12};
const int buttonPins[4] = {2, 3, 4, 5};
const int notes[4] = {262, 330, 392, 523};  // C, E, G và C cao
const int buzzerPin = 8;

int lastState[4] = {HIGH, HIGH, HIGH, HIGH};  // giá trị đọc gần nhất của từng nút

int sequence[4];       // các màu mà bo mạch phát
bool playing = false;  // false cho đến khi một lần nhấn bắt đầu trò chơi
int step = 0;          // số màu người chơi đã lặp lại

// Bật đèn màu i và phát nốt nhạc tương ứng.
void lightOn(int i) {
  digitalWrite(ledPins[i], HIGH);
  tone(buzzerPin, notes[i]);
}

// Tắt đèn màu i và dừng âm thanh.
void lightOff(int i) {
  digitalWrite(ledPins[i], LOW);
  noTone(buzzerPin);
}

// Phát chuỗi: mỗi màu sáng trong 400 ms, rồi im lặng 200 ms.
void playSequence() {
  delay(500);
  for (int i = 0; i < 4; i++) {
    lightOn(sequence[i]);
    delay(400);
    lightOff(sequence[i]);
    delay(200);
  }
}

// Chọn một chuỗi ngẫu nhiên mới và phát chuỗi đó.
void startGame() {
  randomSeed(micros());
  for (int i = 0; i < 4; i++) {
    sequence[i] = random(4);
  }
  playing = true;
  step = 0;
  playSequence();
}

// Người chơi thả nút màu i: đây có phải màu tiếp theo trong chuỗi không?
void checkPress(int i) {
  if (i != sequence[step]) {
    Serial.println("Wrong!");
    playing = false;
    return;
  }
  step++;
  if (step == 4) {
    Serial.println("Well done!");
    playing = false;
  }
}

void setup() {
  for (int i = 0; i < 4; i++) {
    pinMode(ledPins[i], OUTPUT);
    pinMode(buttonPins[i], INPUT_PULLUP);
  }
  Serial.begin(9600);
}

void loop() {
  for (int i = 0; i < 4; i++) {
    int state = digitalRead(buttonPins[i]);
    if (state == LOW && lastState[i] == HIGH) {  // đã nhấn
      lightOn(i);
    }
    if (state == HIGH && lastState[i] == LOW) {  // nhả nút
      lightOff(i);
      if (playing == false) {
        startGame();
      } else {
        checkPress(i);
      }
    }
    lastState[i] = state;
  }
}