Menu
CoddyTech

Lời gọi lồng nhau

Thuộc phần Hàm, ngăn xếp và chuỗi trong hành trình Assembly của Coddy. Bài học 8 trên 33.

Một hàm trợ giúp có thể gọi một hàm trợ giúp khác. Ở đây, cube gọi square và nhân kết quả thêm một lần nữa với rdi:

; cube: rax = rdi * rdi * rdi
cube:
    call square     ; rax = rdi * rdi
    imul rax, rdi
    ret

Mỗi lần gọi call đẩy địa chỉ trả về của riêng nó vào ngăn xếp, nên các địa chỉ xếp chồng lên nhau, địa chỉ mới nhất nằm trên cùng. Khi solve gọi cube và cube gọi square:

; rsp = 1000 trong solve
call cube       ; rsp = 992: trở về solve
; trong cube
call square     ; rsp = 984: trở về cube

Các lần trả về diễn ra theo thứ tự ngược lại. ret của square lấy địa chỉ trên cùng ra khỏi ngăn xếp và quay lại cube (rsp = 992). Sau đó, ret của cube lấy địa chỉ tiếp theo ra khỏi ngăn xếp và quay lại solve (rsp = 1000).

Chuỗi này chỉ hoạt động nếu mỗi thủ tục rời khỏi ngăn xếp như lúc nó bắt đầu: khi ret chạy, địa chỉ trả về của chính nó phải nằm trên cùng. call solve của bộ khung kiểm thử nằm ở đáy chuỗi, vì vậy khi square chạy, có ba địa chỉ trả về trên ngăn xếp.

challenge icon

Thử thách

Dễ

Mã khởi đầu có square (rax = rdi * rdi). Hãy viết cube, hàm này gọi square và trả về rdi * rdi * rdi trong rax. solve nhận n (-1000 đến 1000) trong rdi và trả về lập phương của n trong rax bằng cách gọi cube.

Ví dụ: với đầu vào 2, chương trình in ra 8.

Viết code của bạn trong solution.asm. main.asm bị khóa sẽ đọc đầu vào, gọi solve và in ra số trong rax.

Tự làm thử

bits 64
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall

Tất cả bài học trong Hàm, ngăn xếp và chuỗi

Tự luyện tập: Playground Assembly