Menu
CoddyTech

Giá trị trả về

Thuộc phần Hàm, ngăn xếp và chuỗi trong hành trình Assembly của Coddy. Bài học 12 trên 33.

Hàm trả về kết quả trong rax. Hàm gọi đọc rax ngay sau call, trước khi có thứ gì khác thay đổi giá trị này.

Viết hàm của riêng bạn cũng tuân theo các quy tắc tương tự: một nhãn, code đọc các đối số từ rdi, rsi, rdx và để kết quả trong rax, sau đó là ret.

; sum3(rdi, rsi, rdx): trả về rdi + rsi + rdx
sum3:
    mov rax, rdi
    add rax, rsi
    add rax, rdx
    ret

Khi solve nhận được các đối số giống với những đối số mà nó muốn truyền tiếp, chúng đã nằm trong các thanh ghi phù hợp, nên hàm có thể gọi ngay và dùng kết quả:

solve:
    call sum3       ; rax = tổng của ba giá trị đầu vào
    imul rax, rax, 2
    ret

Nhãn bắt đầu bằng dấu chấm, chẳng hạn như .done, thuộc về nhãn gần nhất phía trước không có dấu chấm. Vì vậy, hai hàm có thể có nhãn .done riêng; hãy đặt tên mỗi hàm bằng một nhãn thông thường như sum3.

rax là thanh ghi kết quả, nên một lần gọi hàm luôn làm thay đổi nó, ngay cả khi gọi một hàm không trả về giá trị hữu ích nào. Đừng bao giờ trông chờ rax giữ nguyên giá trị qua một lệnh call: hãy lưu giá trị đó bằng push trước.

challenge icon

Thử thách

Dễ

Viết một hàm (function) clamp: đặt giá trị trong rdi, giới hạn dưới trong rsi và giới hạn trên trong rdx (tất cả nằm trong khoảng từ -1000 đến 1000, giới hạn dưới không bao giờ lớn hơn giới hạn trên). Hàm trả về giá trị trong rax, tăng lên bằng giới hạn dưới hoặc giảm xuống bằng giới hạn trên nếu giá trị nằm ngoài các giới hạn đó. solve nhận cùng ba số trong rdi, rsi và rdx: gọi clamp rồi trả về kết quả nhân với 2 trong rax.

Ví dụ: với đầu vào 5 1 10, chương trình in ra 10.

Viết code trong solution.asm. Tệp main.asm bị khóa sẽ đọc đầu vào, gọi solve và in ra số trong rax, hoặc tên của thanh ghi cần được hàm gọi bảo toàn mà solve đã thay đổi.

Tự làm thử

bits 64
section .data
    changed_rbx db 'solve changed rbx', 10
    changed_rbp db 'solve changed rbp', 10
    changed_r12 db 'solve changed r12', 10
    changed_r13 db 'solve changed r13', 10
    changed_r14 db 'solve changed r14', 10
    changed_r15 db 'solve changed r15', 10
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rbx, 0x1111111111111111
    mov rbp, 0x2222222222222222
    mov r12, 0x3333333333333333
    mov r13, 0x4444444444444444
    mov r14, 0x5555555555555555
    mov r15, 0x6666666666666666
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    mov rdx, 0x1111111111111111
    lea rsi, [changed_rbx]
    cmp rbx, rdx
    jne .changed
    mov rdx, 0x2222222222222222
    lea rsi, [changed_rbp]
    cmp rbp, rdx
    jne .changed
    mov rdx, 0x3333333333333333
    lea rsi, [changed_r12]
    cmp r12, rdx
    jne .changed
    mov rdx, 0x4444444444444444
    lea rsi, [changed_r13]
    cmp r13, rdx
    jne .changed
    mov rdx, 0x5555555555555555
    lea rsi, [changed_r14]
    cmp r14, rdx
    jne .changed
    mov rdx, 0x6666666666666666
    lea rsi, [changed_r15]
    cmp r15, rdx
    jne .changed
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall
.changed:
    mov eax, 1
    mov edi, 1
    mov edx, 18
    syscall
    jmp .exit

Tất cả bài học trong Hàm, ngăn xếp và chuỗi

Tự luyện tập: Playground Assembly