PUSH ו-POP
חלק מהיחידה פונקציות, מחסנית ומחרוזות במסלול ה-Assembly של Coddy. שיעור 1 מתוך 33.
המחסנית היא אזור בזיכרון שהתוכנית שלך משתמשת בו כדי לשמור ערכים לזמן קצר. האוגר rsp (מצביע המחסנית) מכיל את הכתובת של הערך שנמצא בראש המחסנית. כשהתוכנית שלך מתחילה, rsp כבר מצביע אל תוך המחסנית.
push מניחה ערך בגודל 8 בתים בראש המחסנית. push rdi מפחיתה תחילה 8 מ-rsp, ואז מאחסנת את rdi בכתובת החדשה שב-rsp. המחסנית גדלה כלפי מטה: כל פעולת דחיפה מעבירה את rsp לכתובת נמוכה יותר. כתובות אמיתיות הן מספרים ארוכים, לכן הדוגמאות משתמשות בכתובות קטנות.
; rsp = 1000
push rdi ; rsp = 992, rdi מאוחסן ב־992
push rsi ; rsp = 984, rsi מאוחסן ב־984pop מסירה את הערך העליון. pop rax מעתיקה את 8 הבתים שבכתובת שב-rsp אל rax, ואז מוסיפה 8 ל-rsp.
; rsp = 984
pop rax ; rax = הערך מ־984, rsp = 992
pop rbx ; rbx = הערך מ־992, rsp = 1000אפשר להשתמש ב־push וב־pop כדי להחליף בין שני אוגרים בלי להשתמש באוגר שלישי. פעולת ה־pop הראשונה מחזירה את הערך האחרון שנדחף:
push rdi ; שמור את rdi
push rsi ; שמור את rsi בראש המחסנית
pop rdi ; rdi = הערך הקודם של rsi
pop rsi ; rsi = הערך הקודם של rdiביחידה הזאת האתגרים קוראים לקוד שלך כפי שתוכנית C קוראת לפונקציה. הקובץ הנעול main.asm מציב את הקלטים ב־rdi, ב־rsi, ב־rdx וב־rcx, בסדר הזה, קורא ל־solve, ומדפיס את המספר שהשארת ב־rax. בכל משימה מצוין באילו קלטים היא משתמשת. פרק 3 מסביר למה משתמשים באוגרים האלה.
אתגר
קלsolve מקבלת שני מספרים: הראשון ב-rdi, השני ב-rsi. החליפו בין שני האוגרים באמצעות שתי הוראות push ושתי הוראות pop, ואז החזירו את rdi - rsi ב-rax.
לדוגמה: עבור הקלט 3 10, התוכנית מדפיסה 7.
כתבו את הקוד שלכם בקובץ solution.asm. הקובץ הנעול main.asm קורא את הקלט, קורא ל-solve ומדפיס את המספר שב-rax.
נסו בעצמכם
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscallכל השיעורים ביחידה פונקציות, מחסנית ומחרוזות
תרגלו בעצמכם: Assembly אונליין