سايمون: كرّر النمط

// مدخل واحد لكل لون: الأحمر، الأخضر، الأزرق، الأصفر
const int ledPins[4] = {9, 10, 11, 12};
const int buttonPins[4] = {2, 3, 4, 5};
const int notes[4] = {262, 330, 392, 523};  // C و E و G و C المرتفعة
const int buzzerPin = 8;

int lastState[4] = {HIGH, HIGH, HIGH, HIGH};  // آخر قراءة لكل زر

int sequence[4];       // الألوان التي تشغّلها اللوحة
bool playing = false;  // تبقى false حتى تبدأ ضغطةٌ اللعبة

// أضئ اللون i وشغّل نغمته.
void lightOn(int i) {
  digitalWrite(ledPins[i], HIGH);
  tone(buzzerPin, notes[i]);
}

// أطفئ اللون i وأوقف الصوت.
void lightOff(int i) {
  digitalWrite(ledPins[i], LOW);
  noTone(buzzerPin);
}

// شغّل التسلسل: كل لون لمدة 400 ms، ثم صمت لمدة 200 ms.
void playSequence() {
  delay(500);
  for (int i = 0; i < 4; i++) {
    lightOn(sequence[i]);
    delay(400);
    lightOff(sequence[i]);
    delay(200);
  }
}

// اختر تسلسلًا عشوائيًا جديدًا وشغّله.
void startGame() {
  randomSeed(micros());
  for (int i = 0; i < 4; i++) {
    sequence[i] = random(4);
  }
  playing = true;
  playSequence();
}

void setup() {
  for (int i = 0; i < 4; i++) {
    pinMode(ledPins[i], OUTPUT);
    pinMode(buttonPins[i], INPUT_PULLUP);
  }
}

void loop() {
  for (int i = 0; i < 4; i++) {
    int state = digitalRead(buttonPins[i]);
    if (state == LOW && lastState[i] == HIGH) {  // تم الضغط عليه
      lightOn(i);
    }
    if (state == HIGH && lastState[i] == LOW) {  // تم تحريره
      lightOff(i);
      if (playing == false) {
        startGame();
      }
    }
    lastState[i] = state;
  }
}