المعاملات في السجلات
جزء من قسم الدوال والمكدس والسلاسل النصية في رحلة Assembly على Coddy. الدرس 11 من 33.
اصطلاح الاستدعاء هو مجموعة القواعد التي تلتزم بها كل دالة: أين توضع الوسائط، وأين تعود النتيجة، وأي سجلات يجوز للدالة تغييرها. يمكن للتعليمات البرمجية التي كتبها أشخاص مختلفون، أو أنشأها مترجم C، أن يستدعي بعضها بعضًا لأنها تتبع القواعد نفسها. في Linux x86-64 تُسمى هذه القواعد System V AMD64.
تُمرَّر الوسائط الصحيحة الستة الأولى إلى rdi وrsi وrdx وrcx وr8 وr9، بهذا الترتيب. تُعيد الدالة نتيجتها في rax. لاستدعاء area(3, 4):
mov rdi, 3 ; الوسيط الأول: العرض
mov rsi, 4 ; الوسيط الثاني: الارتفاع
call area ; rax = 12يتبع main.asm المقفل القواعد نفسها: زوّدك كل تحدٍ في هذا القسم بمدخلاته في rdi وrsi وrdx وrcx لأنه يستدعي solve بالطريقة التي يستدعي بها برنامج C دالةً، ويقرأ إجابتك من rax.
يمكن أن تكون الدالة موجودة في ملف آخر. تخبر extern area في أعلى ملفك nasm بأن التسمية area معرّفة في مكان آخر؛ ويضع الملف الذي يعرّفها العلامة global area، ثم يربط الرابط بين الملفين.
extern area
...
call areaيجب أن تكون كل وسيطة في سجلها عند تنفيذ call. يمكنك حساب وسيطة في موضعها: تجعل التعليمة lea rdi, [rdi + rdx * 2] قيمة rdi تساوي rdi + 2 * rdx بتعليمة واحدة، من دون المساس بـ rdx.
التحدي
سهلتستقبل solve عرض صورة في rdi، وارتفاعها في rsi، وحجم إطار في rdx (جميعها من 0 إلى 100). استدعِ area باستخدام العرض بعد إضافة الإطار (العرض + 2 مضروبًا في حجم الإطار) في rdi، والارتفاع بعد إضافة الإطار (الارتفاع + 2 مضروبًا في حجم الإطار) في rsi، وأعِد النتيجة في rax.
مثال: عند الإدخال 3 4 1، يطبع البرنامج 30.
اكتب الكود في solution.asm. يقرأ main.asm المقفل الإدخال، ويستدعي solve، ويطبع الرقم في rax أو اسم سجل محفوظ بواسطة المستدعي غيّره solve.
يحتوي lib.asm على max2 وarea وscore وpoints، مع تعليق على كل منها؛ وهو مقفل.
جرّب بنفسك
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitيتضمن هذا الدرس اختبارًا قصيرًا. ابدأ الدرس للإجابة عليه وتتبّع تقدمك.
جميع دروس الدوال والمكدس والسلاسل النصية
1المكدّس
الإضافة والإزالة (PUSH وPOP)الأخير دخولًا، الأول خروجًاحفظ سجلالقراءة باستخدام [rsp]مراجعة: سجل التراجع4إطارات المكدس والاستدعاء التكراري
المتغيرات المحليةالإطارات باستخدام RBPالاستدعاء التكرارياستدعاءان تكراريانمراجعة: مجموع الأرقام5السلاسل النصية والبايتات
البايتات وASCIIعدّ الأحرفتغيير حالة الأحرفتحويل النص إلى رقمعكس النصمراجعة: المتناظر3اتفاقية استدعاء الدوال
المعاملات في السجلاتالقيم المُعادةالسجلات التي يحفظها المستدعيالسجلات التي يحفظها المستدعىمراجعة: لوحة النتائجتدرّب بنفسك: Playground لـ Assembly