תבנית Singleton

תבנית Singleton מבטיחה שלמחלקה יש בדיוק אובייקט אחד, ומספקת לכל סקריפט דרך אחת לגשת אליו. השתמשו בה עבור דברים שיש מהם רק אחד במשחק: ההגדרות, מערכת השמירה, מנהל הניקוד.

ב-GDScript, ‏static var מחזיק את האובייקט היחיד, ו-static func יוצרת אותו בפעם הראשונה שמישהו מבקש אותו:

# game_settings.gd
class_name GameSettings
extends RefCounted

static var _instance: GameSettings = null

var volume := 50

static func get_instance() -> GameSettings:
	if _instance == null:
		_instance = GameSettings.new()
		print("Creating settings")
	return _instance

_instance שייך למחלקה, ולא לאובייקט, ולכן כל סקריפט רואה את אותו משתנה. הקריאה הראשונה מוצאת אותו ריק ויוצרת את האובייקט; כל קריאה מאוחרת יותר מחזירה את אותו אובייקט.

# main.gd
var a := GameSettings.get_instance()
var b := GameSettings.get_instance()
a.volume = 80
print(b.volume)
print(a == b)

Creating settings
80
true

a ו־b הם שני משתנים שמחזיקים אובייקט אחד, ולכן השינוי שנעשה דרך a מופיע גם דרך b. עבור אובייקטים, == הוא true רק כאשר שני הצדדים הם אותו אובייקט.

GDScript לא יכולה להפוך את _init() לפרטית, ולכן אין דבר שמונע מסקריפט לקרוא ל־GameSettings.new() ולקבל אובייקט שני. הקו התחתון ב־_instance והמתודה get_instance() הם ההסכמה: סקריפטים מבקשים את האובייקט, הם אף פעם לא יוצרים אותו.

בפרויקט Godot, הדרך המקובלת לקבל אובייקט משותף אחד היא באמצעות טעינה אוטומטית: סקריפט שרושמים בהגדרות הפרויקט, ו-Godot יוצר פעם אחת כשהמשחק מתחיל ומעמיד אותו לרשות כל סקריפט לפי שמו. זהו Singleton ש-Godot מנהל עבורך. מגדירים טעינות אוטומטיות בעורך, לכן האתגרים כאן בונים את התבנית בקוד באמצעות static var.