So khớp với biến

Trong bài học Match Statement, mọi mẫu đều là giá trị cố định, như 1: hoặc "bow":. Mẫu cũng có thể là hằng số hoặc biến: match so sánh giá trị với giá trị mà tên đó giữ khi dòng lệnh chạy:

const SECRET := 42
var guess := 42
match guess:
	SECRET:
		print("You found it!")
	_:
		print("Try again")

You found it!

Mẫu mới thứ hai là mẫu liên kết: var theo sau là một tên mới. Giống như _, mẫu này khớp với mọi giá trị, đồng thời lưu giá trị đó vào biến mới, bạn có thể dùng biến này bên trong khối lệnh:

var level := 5
match level:
	1:
		print("Tutorial")
	var n:
		print("Level %d is locked" % n)

Level 5 is locked

Mẫu liên kết hữu ích nhất khi bạn khớp kết quả của một biểu thức không có tên riêng:

var roll_a := 4
var roll_b := 6
match roll_a + roll_b:
	12:
		print("Double six!")
	var total:
		print("You rolled ", total)

You rolled 10

Mẫu binding khớp với mọi thứ, nên nó đứng cuối, như _. Tên của nó phải là tên mới: var level: trong ví dụ thứ hai sẽ gây lỗi vì level đã tồn tại. Mẫu này cũng không thể nằm cùng dòng với các mẫu khác được phân tách bằng dấu phẩy.

match so sánh kiểu dữ liệu một cách nghiêm ngặt: chuỗi "5" không khớp với mẫu 5, và số thực 5.0 cũng vậy. Hãy chuyển văn bản đọc từ đầu vào bằng int() trước khi so khớp với các số.