منصات التعزيز

الدرس 6 من 20 في دورة لعبة Godot: حلبة النيون على Coddy.

الأسهم المتوهجة على المسار هي منصات تعزيز. قُد فوق إحداها لتحصل السيارة على دفعة سرعة تتجاوز max_speed.

احتفظ بمدة استمرار التعزيز في boost_time. توجد المنصات في مجموعة boost_pads، لذا تستطيع السيارة العثور عليها كلها:

for pad in get_tree().get_nodes_in_group("boost_pads"):
	if position.distance_to(pad.position) < 22.0:
		boost_time = maxf(boost_time, 0.4)

ما دام التعزيز مستمرًا، أنقص مدته، وارفع السرعة القصوى بنسبة 30 بالمئة، وادفع السيارة إلى الأمام:

if boost_time > 0.0:
	boost_time -= delta
	top = max_speed * 1.3
	velocity += forward * accel * delta

أظهر ذلك: يتوهج العادم وتشتعل شعلة خلف السيارة.

التحدي

سهل

أضف var boost_time := 0.0 أسفل velocity.
بعد var top := max_speed، أضف التعزيز ثم حلقة الوسادات.
اضبط $Exhaust.emitting = throttle > 0.0 or boost_time > 0.0 و$Flame.visible = boost_time > 0.0.

جرّب بنفسك

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0