Kontrol Noktalarını Sırala

Coddy'nin Godot Oyunu: Neon Pisti kursunda ders 9 / 20.

Bir yarışın turlara ihtiyacı vardır ve bir tur, yalnızca gerçekten pistin çevresini dolaştıysan sayılır. Aksi hâlde çizgiyi geçip geri dönebilir ve çizgiyi tekrar geçebilirsin. Bu yüzden pistte eşit aralıklarla yerleştirilmiş 8 kontrol noktası vardır ve bunlardan sırayla geçilmelidir.

Yarış, Main düğümündeki race.gd dosyasında yer alır. track.offset_of(point), çizgide 0'dan başlayıp track.length değerine kadar bir noktanın pist boyunca ne kadar ileride olduğunu söyler. k numaralı kontrol noktası k * seg konumundadır:

func check_progress() -> void:
	var seg: float = track.length / CHECKPOINTS
	var offset: float = track.offset_of(car.position)
	var target := next_checkpoint * seg
	var gap: float = absf(wrapf(offset - target, -track.length / 2.0, track.length / 2.0))
	if gap < 24.0 and track.is_on_road(car.position):
		next_checkpoint = (next_checkpoint + 1) % CHECKPOINTS

wrapf, 1390 ile 5'in aralarında yalnızca 14 piksel olduğu çizgide aralığın doğru hesaplanmasını sağlar. % CHECKPOINTS, 7 numaralı kontrol noktasından sonra sıradakini çizgi olan 0'a gönderir. is_on_road kullanmak, çimlerin üzerinden kestirme yapmanın sayılmamasını sağlar.

Görev

Orta

race.gd dosyasına const CHECKPOINTS := 8 ve var next_checkpoint := 1 ekle.
@onready ile track ($Track) ve car ($Car) değişkenlerini al.
check_progress fonksiyonunu yaz ve _physics_process içinden çağır.

Kendin dene

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO
var boost_time := 0.0
var boost_charge := 0.0

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")
	if Input.is_action_just_pressed("action") and boost_charge >= 1.0:
		boost_charge = 0.0
		boost_time = 1.0
	boost_charge = minf(1.0, boost_charge + delta / 10.0)
	$"../HUD/Boost".scale.x = boost_charge

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	var grip_now := grip
	if boost_time > 0.0:
		boost_time -= delta
		top = max_speed * 1.3
		velocity += forward * accel * delta
	for pad in get_tree().get_nodes_in_group("boost_pads"):
		if position.distance_to(pad.position) < 22.0:
			boost_time = maxf(boost_time, 0.4)
	for oil in get_tree().get_nodes_in_group("oil"):
		if position.distance_to(oil.position) < 20.0:
			grip_now = grip * 0.12
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip_now * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0 or boost_time > 0.0
	$Flame.visible = boost_time > 0.0