[rsp] ile Okuma
Coddy'nin Assembly Journey'sinin Fonksiyonlar, Yığın ve Dizeler bölümünün bir parçası. Ders 4 / 33.
rsp bir adres tutar, bu yüzden yığını diğer bellekler gibi okuyabilirsin. mov rax, [rsp], en üstteki değeri pop etmeden rax içine kopyalar: rsp bulunduğu yerde kalır.
Her yuva 8 bayttır ve daha eski değerler daha yüksek adreslerde bulunur. 10, 20 ve 30'u yığına ekledikten sonra:
push 10
push 20
push 30
mov rax, [rsp] ; rax = 30, en üstteki
mov rbx, [rsp + 8] ; rbx = 20
mov rcx, [rsp + 16] ; rcx = 10, ilk yığına eklenenOkuma hiçbir şeyi kaldırmaz. İşin bittiğinde alanı geri ver: her değeri tek tek yığından çıkar ya da üç değer için (3 kez 8 bayt) add rsp, 24 komutuyla hepsini bir kerede kaldır.
Yığın, ret'ten önce dengelenmelidir. solve, dönüş adresini [rsp]'den okuyan ret ile sona erer. İttiğin bir değer hâlâ en üstteyse ret bunu adres olarak kullanır ve program herhangi bir şey yazdırmadan çöker.
Görev
Kolaysolve, rdi, rsi, rdx ve rcx içinde dört sayı alır. Bunları bu sırayla yığına ekle. Yığından çıkarmadan, en üstten ikinci değeri ve en alttaki (ilk eklenen) değeri [rsp + ...] ile oku ve toplamlarını rax içinde döndür. ret öncesinde dört değerin tamamını kaldır.
Örnek: 1 2 3 4 girdisi için program 4 yazdırır.
Kodunu solution.asm dosyasına yaz. Kilitli main.asm girdiyi okur, solve işlevini çağırır ve rax içindeki sayıyı yazdırır.
Kendin dene
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscallBu ders kısa bir quiz içerir. Soruları yanıtlamak ve ilerlemeni kaydetmek için derse başla.
Fonksiyonlar, Yığın ve Dizeler bölümündeki tüm dersler
Kendi başına pratik yap: Assembly playground