İki Özyinelemeli Çağrı
Coddy'nin Assembly Journey'sinin Fonksiyonlar, Yığın ve Dizeler bölümünün bir parçası. Ders 19 / 33.
Fibonacci sayıları 0, 1, 1, 2, 3, 5, 8 şeklinde başlar: her biri kendisinden önceki iki sayının toplamıdır. Bir fonksiyon olarak: fib(n) = fib(n - 1) + fib(n - 2); temel durumlar fib(0) = 0 ve fib(1) = 1 şeklindedir. Her çağrı iki çağrı yapar.
İlk çağrı sonucunu rax içinde bırakır ve ikinci çağrı rax değerinin üzerine yazar. İlk sonucu rbx gibi çağrılan tarafından korunan bir yazmaçta tut: rbx kullanan her işlev onu geri yükler, böylece çağrıdan sonra da korunur. Önce çağıranın rbx değerini kaydet.
rdi içinde n ve rax içinde fib(n) olacak şekilde fonksiyonun tamamı:
fib:
cmp rdi, 2
jl .base
push rbx
push rdi
dec rdi
call fib
mov rbx, rax
pop rdi
sub rdi, 2
call fib
add rax, rbx
pop rbx
ret
.base:
mov rax, rdi
retPush ve pop işlemleri ters sırayla eşleşir: başlangıçta push rbx ve push rdi, ikinci çağrıdan önce pop rdi, ret öncesinde pop rbx.
Seviye başına iki çağrı birikir: fib(25) yaklaşık 240.000 çağrı yapar. Her çağrı, bir sonraki başlamadan önce döndüğü için yığın küçük kalır: en derin zincir 25 çağrıdır.
Görev
KolayÖzyinelemeli bir fib fonksiyonu yaz: n, rdi içinde (0 ile 25 arasında); Fibonacci sayısı fib(n), rax içinde olsun; fib(0) = 0 ve fib(1) = 1. solve, n değerini rdi içinde alır, fib fonksiyonunu çağırır ve sonucunu rax içinde döndürür.
Örnek: 10 girdisi için program 55 yazdırır.
Kodunu solution.asm dosyasına yaz. Kilitli main.asm, girdiyi okur, solve fonksiyonunu çağırır ve rax içindeki sayıyı ya da solve fonksiyonunun değiştirdiği çağrı sırasında korunması gereken yazmacın adını yazdırır.
Kendin dene
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitBu ders kısa bir quiz içerir. Soruları yanıtlamak ve ilerlemeni kaydetmek için derse başla.
Fonksiyonlar, Yığın ve Dizeler bölümündeki tüm dersler
4Yığın Çerçeveleri ve Özyineleme
Yerel DeğişkenlerRBP ile ÇerçevelerÖzyinelemeİki Özyinelemeli ÇağrıÖzet: Rakamların ToplamıKendi başına pratik yap: Assembly playground