Menu
CoddyTech

Özyineleme

Coddy'nin Assembly Journey'sinin Fonksiyonlar, Yığın ve Dizeler bölümünün bir parçası. Ders 18 / 33.

Özyinelemeli bir fonksiyon, probleminin daha küçük bir sürümü üzerinde kendisini çağırır. n sayısının faktöriyeli, n ile n - 1 sayısının faktöriyelinin çarpımıdır: 4! = 4 * 3!. Zincir 1! = 1 noktasında durur; 0! = 1 de geçerlidir.

Her özyinelemeli fonksiyonun bir temel duruma ihtiyacı vardır: kendi kendini çağırmadan yanıtladığı bir girdi. Bu olmadan çağrılar hiç durmaz. Her çağrı bir dönüş adresini yığına ekler ve program çökene kadar yığının alanı tükenir.

factorial, n değerini rdi içinde alır ve n! değerini rax içinde döndürür:

factorial:
    cmp rdi, 1
    jg .recurse
    mov eax, 1
    ret
.recurse:
    push rdi
    dec rdi
    call factorial
    pop rdi
    imul rax, rdi
    ret

İç çağrı rdi değerini değiştirir, bu yüzden her çağrı, çağrı yapmadan önce kendi n değerini yığına ekler ve çağrıdan sonra yığından çıkarır. Her çağrının kendine ait bir dönüş adresi ve yığında saklanan kendi n değeri vardır.

factorial(3) için: 3'ü kaydeder ve factorial(2) işlevini çağırır; bu da 2'yi kaydeder ve factorial(1) işlevini çağırır. Bu işlev 1 döndürür. Ardından dönüşler ters sırayla gerçekleşir: 2 * 1 = 2, sonra 3 * 2 = 6.

challenge icon

Görev

Kolay

Özyinelemeli bir factorial işlevi yaz: n, rdi içinde (0 ile 20 arasında), n! ise rax içinde olsun; 0! ve 1! 1'e eşittir. solve, n değerini rdi içinde alır, factorial işlevini çağırır ve sonucunu rax içinde döndürür.

Örnek: 5 girdisi için program 120 yazdırır.

Kodunu solution.asm dosyasına yaz. Kilitli main.asm girdiyi okur, solve işlevini çağırır ve rax içindeki sayıyı ya da solve işlevinin değiştirdiği, çağrılan tarafından korunması gereken yazmaç adını yazdırır.

Kendin dene

bits 64
section .data
    changed_rbx db 'solve changed rbx', 10
    changed_rbp db 'solve changed rbp', 10
    changed_r12 db 'solve changed r12', 10
    changed_r13 db 'solve changed r13', 10
    changed_r14 db 'solve changed r14', 10
    changed_r15 db 'solve changed r15', 10
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rbx, 0x1111111111111111
    mov rbp, 0x2222222222222222
    mov r12, 0x3333333333333333
    mov r13, 0x4444444444444444
    mov r14, 0x5555555555555555
    mov r15, 0x6666666666666666
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    mov rdx, 0x1111111111111111
    lea rsi, [changed_rbx]
    cmp rbx, rdx
    jne .changed
    mov rdx, 0x2222222222222222
    lea rsi, [changed_rbp]
    cmp rbp, rdx
    jne .changed
    mov rdx, 0x3333333333333333
    lea rsi, [changed_r12]
    cmp r12, rdx
    jne .changed
    mov rdx, 0x4444444444444444
    lea rsi, [changed_r13]
    cmp r13, rdx
    jne .changed
    mov rdx, 0x5555555555555555
    lea rsi, [changed_r14]
    cmp r14, rdx
    jne .changed
    mov rdx, 0x6666666666666666
    lea rsi, [changed_r15]
    cmp r15, rdx
    jne .changed
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall
.changed:
    mov eax, 1
    mov edi, 1
    mov edx, 18
    syscall
    jmp .exit

Fonksiyonlar, Yığın ve Dizeler bölümündeki tüm dersler

Kendi başına pratik yap: Assembly playground