Кадры с RBP
Часть раздела Функции, стек и строки путешествия по Assembly на Coddy. Урок 17 из 33.
При использовании локальных переменных, команд помещения данных в стек и вызовов rsp постоянно меняется, поэтому [rsp + 8] может означать разные ячейки в разных точках функции. Стековый кадр задаёт фиксированную точку отсчёта: регистр rbp (указатель базы).
Функция с кадром начинается с трёх строк — пролога:
push rbp ; сохранить rbp вызывающей функции
mov rbp, rsp ; rbp указывает на этот стековый кадр
sub rsp, 16 ; две локальные переменныеЛокальные переменные находятся ниже rbp, по адресам [rbp - 8] и [rbp - 16]. Эти адреса указывают на одни и те же ячейки на протяжении всей функции, сколько бы значений вы ни поместили в стек позже.
Эпилог отменяет пролог. mov rsp, rbp сразу удаляет все локальные переменные, а pop rbp возвращает вызывающей функции её rbp:
mov rsp, rbp ; освобождаем место, занятое локальными переменными
pop rbp ; восстановлен rbp вызывающей функции
retrbp — регистр, сохраняемый вызываемой функцией, поэтому именно команда push в начале и команда pop в конце сохраняют его значение неизменным для вызывающей функции. Выше rbp находятся сохранённое значение rbp по адресу [rbp] и адрес возврата по адресу [rbp + 8]. Другие регистры, сохраняемые вызываемой функцией, которые вы используете, помещаются в стек сразу после пролога и извлекаются из него непосредственно перед mov rsp, rbp:
push rbp
mov rbp, rsp
sub rsp, 16
push rbx
; ... функция ...
pop rbx
mov rsp, rbp
pop rbp
retЗадание
Легкоsolve получает n (от 1 до 50) в rdi. Используй стековый кадр с двумя локальными переменными: [rbp - 8] для наибольшего значения score, встреченного к этому моменту, и [rbp - 16] для его уровня. Проверь уровни от 1 до n и сохрани первый уровень с наибольшим значением score. Верни level * 100 + score в rax.
Пример: для входных данных 5 программа выводит 509.
Напиши свой код в solution.asm. Заблокированный файл main.asm считывает входные данные, вызывает solve и выводит число в rax или имя регистра, сохраняемого вызываемой функцией, который изменил solve.
В lib.asm содержатся max2, area, score и points, с комментарием для каждого; файл заблокирован.
Попробуйте сами
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitВ этом уроке есть небольшой тест. Начните урок, чтобы ответить на вопросы и сохранить прогресс.
Все уроки раздела Функции, стек и строки
1Стек
PUSH и POPПоследним пришёл — первым ушёлСохранение регистраЧтение с помощью [rsp]Повторение: история отмен4Кадры стека и рекурсия
Локальные переменныеКадры с RBPРекурсияДва рекурсивных вызоваПовторение: сумма цифрПотренируйтесь самостоятельно: Песочница Assembly