Написание вспомогательной функции
Часть раздела Функции, стек и строки путешествия по Assembly на Coddy. Урок 7 из 33.
У вспомогательной процедуры есть соглашение с вызывающим её кодом: в каком регистре находится входное значение и в каком регистре будет результат. Запишите это соглашение в комментарии над меткой, чтобы каждый вызывающий код знал, что нужно установить и что считать.
; square: rax = rdi * rdi
square:
mov rax, rdi
imul rax, rdi
retВспомогательную функцию можно вызывать много раз. Перед каждым вызовом задавайте входной регистр; после вызова сохраните результат из rax, прежде чем следующий вызов перезапишет его:
mov rdi, 3
call square ; rax = 9
mov r8, rax ; сохраняем 9
mov rdi, 4
call square ; rax = 16
add rax, r8 ; rax = 25Вызывающая функция выше сохраняет своё значение 9 в r8, и это работает, потому что square никогда не затрагивает r8. Если бы вспомогательная функция использовала r8 для своей работы, это значение 9 было бы потеряно. Ограничивай вспомогательную функцию регистрами, указанными в комментарии к ней.
Имя вспомогательной функции — это обычная метка без точки. Метка, начинающаяся с точки, например .loop, относится к расположенной над ней обычной метке, поэтому у двух вспомогательных функций может быть своя метка .loop.
count_up:
.loop: ; count_up.loop
ret
count_down:
.loop: ; count_down.loop
retЗадание
ЛегкоНапиши вспомогательную функцию square, которая возвращает rdi * rdi в rax. Функция solve получает a в rdi и b в rsi (оба числа — от -1000 до 1000). Вызови square по одному разу для каждого числа и верни a * a + b * b в rax.
Пример: для входных данных 3 4 программа выводит 25.
Напиши код в solution.asm. Заблокированный файл main.asm считывает входные данные, вызывает solve и выводит число из rax.
Попробуйте сами
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscallВ этом уроке есть небольшой тест. Начните урок, чтобы ответить на вопросы и сохранить прогресс.
Все уроки раздела Функции, стек и строки
1Стек
PUSH и POPПоследним пришёл — первым ушёлСохранение регистраЧтение с помощью [rsp]Повторение: история отмен4Кадры стека и рекурсия
Локальные переменныеКадры с RBPРекурсияДва рекурсивных вызоваПовторение: сумма цифр2CALL и RET
CALL и RETНаписание вспомогательной функцииВложенные вызовыСтек должен быть сбалансированПовторение: стоимость заказаПотренируйтесь самостоятельно: Песочница Assembly