Рекурсия
Часть раздела Функции, стек и строки путешествия по Assembly на Coddy. Урок 18 из 33.
Рекурсивная функция вызывает сама себя для меньшей версии своей задачи. Факториал n — это n, умноженное на факториал n - 1: 4! = 4 * 3!. Цепочка заканчивается на 1! = 1, а 0! = 1 тоже.
Каждой рекурсивной функции нужен базовый случай: входные данные, на которые она отвечает, не вызывая саму себя. Без него вызовы никогда не прекратятся. Каждый вызов помещает в стек адрес возврата, и в стеке заканчивается место, пока программа не аварийно завершится.
factorial принимает n в rdi и возвращает n! в rax:
factorial:
cmp rdi, 1
jg .recurse
mov eax, 1
ret
.recurse:
push rdi
dec rdi
call factorial
pop rdi
imul rax, rdi
retВнутренний вызов изменяет rdi, поэтому каждый вызов помещает собственное значение n в стек перед вызовом и извлекает его после. У каждого вызова есть собственный адрес возврата и собственное сохранённое значение n в стеке.
Для factorial(3): она сохраняет 3 и вызывает factorial(2), которая сохраняет 2 и вызывает factorial(1), которая возвращает 1. Затем возвраты выполняются в обратном порядке: 2 * 1 = 2, затем 3 * 2 = 6.
Задание
ЛегкоНапиши рекурсивную функцию factorial: n находится в rdi (от 0 до 20), n! — в rax, при этом 0! и 1! равны 1. Функция solve получает n в rdi, вызывает factorial и возвращает результат в rax.
Пример: при вводе 5 программа выводит 120.
Напиши свой код в solution.asm. Заблокированный файл main.asm считывает ввод, вызывает solve и выводит число из rax либо имя регистра, который должна сохранять вызываемая функция, но который изменила функция solve.
Попробуйте сами
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitВсе уроки раздела Функции, стек и строки
1Стек
PUSH и POPПоследним пришёл — первым ушёлСохранение регистраЧтение с помощью [rsp]Повторение: история отмен4Кадры стека и рекурсия
Локальные переменныеКадры с RBPРекурсияДва рекурсивных вызоваПовторение: сумма цифрПотренируйтесь самостоятельно: Песочница Assembly