Средняя оценка

Часть раздела Логика и потоки выполнения путешествия по GDScript на Coddy. Урок 46 из 78.

Задание

Легко

Вычислите среднюю оценку ученика. Сохраните всё, что вы написали на предыдущих шагах.

1. Функция. Ниже остальных функций напишите calculate_average_grade(student_name: String) -> float:

Если в student_records нет этого имени, выведите Student '<name>' not found. и верните -1.0. Настоящее среднее значение не может быть отрицательным, поэтому вызывающий код сможет определить, что ученик не найден.
Если у ученика пока нет оценок, верните 0.0.
В противном случае верните сумму оценок, делённую на их количество, в виде значения типа float.

2. Команда. Добавьте эту ветку для average <name> перед ["show"]. Она выводит среднее значение с двумя десятичными знаками, если ученик найден:

["average", var student]:
	var average := calculate_average_grade(student)
	if average >= 0:
		print("Average grade of '%s': %.2f" % [student, average])

Для команд

add Alice 20 Math Physics
add Bob 22 Biology Chemistry
grade Alice 90
grade Alice 85
grade Bob 75
average Alice
average Bob
average Charlie
exit

вывод будет таким:

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Grade 90 added for student 'Alice'.
Grade 85 added for student 'Alice'.
Grade 75 added for student 'Bob'.
Average grade of 'Alice': 87.50
Average grade of 'Bob': 75.00
Student 'Charlie' not found.
Goodbye!

Попробуйте сами

extends Node

# Для каждого студента: имя -> {"age": int, "grades": Array, "courses": множество названий курсов}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)