Сопоставление с переменными

В уроке Оператор match каждый шаблон был литеральным значением, например 1: или "bow":. Шаблоном также может быть константа или переменная: match сравнивает значение с тем, что хранится в этом имени в момент выполнения строки:

const SECRET := 42
var guess := 42
match guess:
	SECRET:
		print("You found it!")
	_:
		print("Try again")

You found it!

Второй новый шаблон — это шаблон связывания: var, за которым следует новое имя. Как и _, он соответствует любому значению, а также сохраняет это значение в новой переменной, которую можно использовать внутри её блока:

var level := 5
match level:
	1:
		print("Tutorial")
	var n:
		print("Level %d is locked" % n)

Level 5 is locked

Шаблон связывания наиболее полезен, когда вы сопоставляете результат выражения, у которого нет собственного имени:

var roll_a := 4
var roll_b := 6
match roll_a + roll_b:
	12:
		print("Double six!")
	var total:
		print("You rolled ", total)

You rolled 10

Шаблон связывания соответствует чему угодно, поэтому он идет последним, как _. Его имя должно быть новым: var level: во втором примере было бы ошибкой, потому что level уже существует. Он также не может находиться в одной строке с другими шаблонами, разделенными запятыми.

match строго сравнивает типы: строка "5" не соответствует шаблону 5, как и число с плавающей точкой 5.0. Преобразуй текст, считанный из ввода, с помощью int(), прежде чем сравнивать его с числами.