Bileşik Kalıp

Composite tasarım deseni, tek bir nesnenin ve bir nesne grubunun aynı yöntemlere sahip olduğu ağaçlar oluşturur; böylece kod, bütün bir grubu tek bir öğe gibi ele alabilir. Bir çanta öğeler içerir, bir çanta başka çantalar içerebilir ve ağırlığını hepsine aynı şekilde sorabilirsiniz.

Her iki tür de ortak bir soyut üst sınıfı paylaşır:

# entry.gd
@abstract
class_name Entry
extends RefCounted

var entry_name: String

@abstract func get_weight() -> int
@abstract func display(indent: String) -> void

Yaprak tek bir öğedir:

# item.gd
class_name Item
extends Entry

var weight: int

func _init(n: String, w: int) -> void:
	entry_name = n
	weight = w

func get_weight() -> int:
	return weight

func display(indent: String) -> void:
	print(indent, entry_name, " (", weight, ")")

Bileşik, başka girdileri içinde tutar ve her birine sorarak yanıt verir. Bir çanta kendi başına 1 ağırlığındadır:

# bag.gd
class_name Bag
extends Entry

var contents: Array[Entry] = []

func _init(n: String) -> void:
	entry_name = n

func add(entry: Entry) -> void:
	contents.append(entry)

func get_weight() -> int:
	var total := 1
	for entry in contents:
		total += entry.get_weight()
	return total

func display(indent: String) -> void:
	print(indent, entry_name, " [", get_weight(), "]")
	for entry in contents:
		entry.display(indent + "  ")

# main.gd
var pouch := Bag.new("Pouch")
pouch.add(Item.new("Gem", 2))
var backpack := Bag.new("Backpack")
backpack.add(Item.new("Sword", 8))
backpack.add(pouch)
backpack.display("")

Backpack [12]
  Sword (8)
  Pouch [3]
    Gem (2)

Bag.get_weight() bir girdinin eşya mı yoksa çanta mı olduğunu asla kontrol etmez: her biri için aynı yöntemi çağırır ve içindeki bir çanta kendi içeriğine sorarak yanıt verir. Bu özyineleme, ne kadar derin olursa olsun tüm ağaç yapısını dolaşır.

Bağlantılar tek yönlüdür; bir torbadan içindekilere gider. Her girdi içinde bulunduğu torbayı da saklasaydı, her torba ve girdileri birbirini işaret ederdi; bu da hiçbir zaman serbest bırakılmayan bir başvuru döngüsü oluştururdu. Bir girdinin nerede olduğunu bilmesi gerektiğinde, display() girintiyi nasıl geçiriyorsa bu bilgiyi de bir bağımsız değişken olarak aşağıya aktarın.