Argumen di Register
Termasuk bagian Fungsi, Stack, dan String dalam perjalanan Assembly di Coddy. Pelajaran 11 dari 33.
Konvensi pemanggilan adalah sekumpulan aturan yang disepakati setiap fungsi: di mana argumen diletakkan, di mana hasil dikembalikan, dan register mana yang boleh diubah oleh fungsi. Kode yang ditulis oleh orang berbeda, atau dibuat oleh compiler C, dapat saling memanggil karena mengikuti aturan yang sama. Di Linux x86-64, aturan ini disebut System V AMD64.
Enam argumen integer pertama ditempatkan di rdi, rsi, rdx, rcx, r8, dan r9, secara berurutan. Fungsi mengembalikan hasilnya di rax. Untuk memanggil area(3, 4):
mov rdi, 3 ; argumen pertama: lebar
mov rsi, 4 ; argumen kedua: tinggi
call area ; rax = 12main.asm yang terkunci mengikuti aturan yang sama: setiap tantangan di bagian ini telah memberikan input-nya di rdi, rsi, rdx, dan rcx karena bagian ini memanggil solve seperti program C memanggil fungsi, lalu membaca jawabanmu dari rax.
Sebuah fungsi bisa berada di file lain. extern area di bagian atas file-mu memberi tahu nasm bahwa label area didefinisikan di tempat lain. File yang mendefinisikannya menandainya dengan global area, lalu linker menggabungkan keduanya.
extern area
...
call areaSetiap argumen harus berada di register-nya saat call dijalankan. Kamu dapat menghitung argumen secara langsung: lea rdi, [rdi + rdx * 2] mengatur rdi menjadi rdi + 2 * rdx dalam satu instruksi, tanpa mengubah rdx.
Tantangan
Mudahsolve menerima lebar gambar dalam rdi, tingginya dalam rsi, dan ukuran bingkai dalam rdx (semuanya dari 0 hingga 100). Panggil area dengan lebar yang sudah diberi bingkai (lebar + 2 kali ukuran bingkai) dalam rdi dan tinggi yang sudah diberi bingkai (tinggi + 2 kali ukuran bingkai) dalam rsi, lalu kembalikan hasilnya dalam rax.
Contoh: untuk input 3 4 1, program mencetak 30.
Tulis kodemu di solution.asm. main.asm yang terkunci membaca input, memanggil solve, lalu mencetak angka dalam rax, atau nama register callee-saved yang diubah oleh solve.
lib.asm berisi max2, area, score, dan points, masing-masing disertai komentar; file ini terkunci.
Coba sendiri
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitPelajaran ini berisi kuis singkat. Mulai pelajarannya untuk menjawab kuis dan melacak progresmu.
Semua pelajaran di Fungsi, Stack, dan String
1Tumpukan
PUSH dan POPMasuk Terakhir, Keluar PertamaMenyimpan RegisterMembaca dengan [rsp]Ringkasan: Riwayat Pembatalan4Stack Frame dan Rekursi
Variabel LokalFrame dengan RBPRekursiDua Pemanggilan RekursifRingkasan: Jumlah Digit3Konvensi Pemanggilan
Argumen di RegisterNilai KembalianRegister yang Disimpan oleh PemanggilRegister yang Disimpan oleh Fungsi yang DipanggilRekap: Papan SkorLatihan sendiri: Playground Assembly