Menu
CoddyTech

PUSH dan POP

Termasuk bagian Fungsi, Stack, dan String dalam perjalanan Assembly di Coddy. Pelajaran 1 dari 33.

Stack adalah area memori yang digunakan programmu untuk menyimpan nilai dalam waktu singkat. Register rsp (stack pointer) menyimpan alamat nilai yang berada di bagian paling atas stack. Saat programmu dimulai, rsp sudah menunjuk ke dalam stack.

push meletakkan nilai 8 byte di bagian atas. push rdi terlebih dahulu mengurangi rsp sebesar 8, lalu menyimpan rdi di alamat baru pada rsp. Stack tumbuh ke bawah: setiap push memindahkan rsp ke alamat yang lebih rendah. Alamat sebenarnya berupa angka yang panjang, jadi contoh-contoh ini menggunakan angka kecil.

; rsp = 1000
push rdi        ; rsp = 992, rdi disimpan di 992
push rsi        ; rsp = 984, rsi disimpan di 984

pop mengambil nilai teratas. pop rax menyalin 8 byte pada alamat di rsp ke rax, lalu menambahkan 8 ke rsp.

; rsp = 984
pop rax         ; rax = nilai dari 984, rsp = 992
pop rbx         ; rbx = nilai dari 992, rsp = 1000

Push dan pop dapat menukar dua register tanpa register ketiga. pop pertama mengembalikan nilai terakhir yang di-push:

push rdi        ; simpan rdi
push rsi        ; simpan rsi di paling atas
pop rdi         ; rdi = nilai rsi sebelumnya
pop rsi         ; rsi = nilai rdi sebelumnya

Di bagian ini, tantangan memanggil kodemu seperti program C memanggil fungsi. main.asm yang terkunci menempatkan input di rdi, rsi, rdx, dan rcx, sesuai urutan tersebut, memanggil solve, lalu mencetak angka yang kamu tinggalkan di rax. Setiap tugas menyebutkan input yang digunakannya. Bab 3 menjelaskan alasan penggunaan register-register ini.

challenge icon

Tantangan

Mudah

solve menerima dua angka: yang pertama di rdi, yang kedua di rsi. Tukar kedua register dengan dua instruksi push dan dua instruksi pop, lalu kembalikan rdi - rsi di rax.

Contoh: untuk input 3 10, program mencetak 7.

Tulis kodemu di solution.asm. main.asm yang dikunci membaca input, memanggil solve, dan mencetak angka di rax.

Coba sendiri

bits 64
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall

Semua pelajaran di Fungsi, Stack, dan String

Latihan sendiri: Playground Assembly