Byte dan ASCII
Termasuk bagian Fungsi, Stack, dan String dalam perjalanan Assembly di Coddy. Pelajaran 21 dari 33.
Satu karakter disimpan sebagai satu byte: kode ASCII-nya. 'A' adalah 65, 'a' adalah 97, digit '0' adalah 48, dan spasi bernilai 32. Teks di memori berupa deretan byte ini, satu byte untuk setiap karakter.
Di bab ini, main.asm yang terkunci membaca satu baris teks dan meneruskan alamatnya ke solve dalam rdi. Teks berakhir dengan byte nol, angka 0 yang tidak digunakan oleh karakter apa pun. Kode yang menelusuri teks berhenti saat membaca angka nol itu. C menyimpan string dengan cara yang sama.
movzx eax, byte [rdi] membaca satu byte dan mengisi sisa bagian rax dengan nol. mov al, [rdi] biasa hanya mengubah byte paling rendah dan mempertahankan byte atas rax yang lama, jadi membandingkan seluruh rax setelahnya bisa keliru.
movzx eax, byte [rdi] ; rax = byte pertama, untuk 'Hi' 72
movzx ecx, byte [rdi + 1] ; rcx = byte kedua, 105Setiap karakter berukuran satu byte, jadi karakter berikutnya berada di alamat berikutnya: inc rdi, atau gunakan register indeks dalam [rdi + rcx]. Perulangan ini berhenti pada byte nol:
xor ecx, ecx
.next:
movzx eax, byte [rdi + rcx]
test eax, eax
jz .end
inc rcx
jmp .next
.end:Dalam NASM, karakter di dalam tanda kutip adalah kodenya: cmp al, 'a' adalah instruksi yang sama dengan cmp al, 97. Tanda kutip membuat kode lebih mudah dibaca daripada angka.
Tantangan
Mudahsolve menerima alamat teks di rdi; teks berakhir dengan byte nol. Kembalikan jumlah byte sebelum byte nol dalam rax. Teks kosong menghasilkan 0.
Contoh: untuk input hello, program mencetak 5.
Tulis kodemu di solution.asm. main.asm yang terkunci membaca satu baris teks, memanggil solve, lalu mencetak angka dalam rax.
Coba sendiri
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 257
text_buffer resb 256
output_buffer resb 32
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jg .trim
xor eax, eax
.trim:
test rax, rax
jz .ended
movzx edx, byte [input_buffer + rax - 1]
cmp dl, 10
je .drop
cmp dl, 13
jne .ended
.drop:
dec rax
jmp .trim
.ended:
mov byte [input_buffer + rax], 0
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
lea rdi, [input_buffer]
lea rsi, [text_buffer]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitSemua pelajaran di Fungsi, Stack, dan String
1Tumpukan
PUSH dan POPMasuk Terakhir, Keluar PertamaMenyimpan RegisterMembaca dengan [rsp]Ringkasan: Riwayat Pembatalan4Stack Frame dan Rekursi
Variabel LokalFrame dengan RBPRekursiDua Pemanggilan RekursifRingkasan: Jumlah DigitLatihan sendiri: Playground Assembly