=СЧЁТЕСЛИ(A2:A8;"*") считает ячейки в A2:A8, в которых стоит текст. Звёздочка это подстановочный знак для «любых символов», и она подходит только к тексту, поэтому числа, даты, TRUE/FALSE и пустые ячейки не считаются. СЧЁТЕСЛИ по-английски называется COUNTIF; в таблице ниже формулы записаны по-английски, но их можно вводить и по-русски, с точкой с запятой.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Entry | What | Count | |
| 2 | Apple | Text | 3 | |
| 3 | 12 | Not empty | 6 | |
| 4 | Numbers and dates | 2 | ||
| 5 | Pear | Empty | 1 | |
| 6 | 2026-01-05 | |||
| 7 | TRUE | |||
| 8 | n/a |
=СЧЁТЕСЛИ(A2:A8;"*")D2 считает Apple, Pear и n/a: 3. СЧЁТЗ (COUNTA) считает каждую заполненную ячейку, 6, а СЧЁТ (COUNT) два числа (дата это число). Введите 25 в A4, и D3 и D4 вырастут, а D2 останется 3; введите вместо этого Plum, и вырастут D2 и D3, а D4 останется 2. СЧЁТ и СЧЁТЗ сравниваются на отдельной странице.
Число, введённое с апострофом впереди, например '007, это текст, поэтому "*" его считает. Чтобы считать только ячейки хотя бы с одним символом, используйте "?*": ? должен совпасть с одним символом, поэтому формула, которая возвращает пустую строку (""), никогда не считается.
Подсчёт ячеек с определённым текстом
Чтобы посчитать ячейки, где слово встречается в любом месте, поставьте звёздочку с обеих сторон. Без звёздочек должна совпасть вся ячейка.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Condition | Count | |
| 2 | Apple | contains apple | 5 | |
| 3 | Pineapple | exactly apple | 1 | |
| 4 | Pear | starts with apple | 3 | |
| 5 | apple juice | word in C6 | 1 | |
| 6 | Plum | juice | ||
| 7 | Green apple | apple, case-sensitive | 3 | |
| 8 | Apple cider |
=СЧЁТЕСЛИ(A2:A8;"*apple*")"*apple*" подходит к пяти товарам. "apple" без звёздочек подходит только к ячейке, где стоит ровно Apple (СЧЁТЕСЛИ не учитывает регистр), а "apple*" к трём, которые с него начинаются. D5 берёт слово из C6, поэтому туда можно ввести любое слово. D7 учитывает регистр: НАЙТИ (FIND), в отличие от СЧЁТЕСЛИ, отличает apple от Apple, поэтому считаются только Pineapple, apple juice и Green apple. -- превращает результаты TRUE/FALSE в 1 и 0, чтобы СУММПРОИЗВ (SUMPRODUCT) их сложила.
Если ячейка содержит текст, вернуть значение
Чтобы отметить каждую строку, проверяйте по одной ячейке. ПОИСК("apple";A2) возвращает позицию, с которой начинается apple, или #ЗНАЧ! (по-английски #VALUE!, так ошибки показывают таблицы на этой странице), если его нет. ЕЧИСЛО (ISNUMBER) превращает это в ИСТИНА или ЛОЖЬ, а ЕСЛИ выбирает результат.
| A | B | C | |
|---|---|---|---|
| 1 | Product | Contains apple? | Any text? |
| 2 | Apple | Yes | Text |
| 3 | Pear | No | Text |
| 4 | Pineapple | Yes | Text |
| 5 | 42 | No | Not text |
| 6 | Green apple | Yes | Text |
| 7 | 2026-02-01 | No | Not text |
=ЕСЛИ(ЕЧИСЛО(ПОИСК("apple";A2));"Yes";"No")Оба столбца протянуты вниз. Столбец B показывает Yes для Apple, Pineapple и Green apple. Столбец C использует ЕТЕКСТ (ISTEXT), которая отвечает на другой вопрос: есть ли в ячейке текст вообще. 42 и дата это числа, поэтому они «Not text». Когда регистр важен, используйте НАЙТИ вместо ПОИСК. Больше об этих двух функциях и о том, почему регистр не учитывает именно ПОИСК, на странице НАЙТИ и ПОИСК.
=ЕСЛИ(СЧЁТЕСЛИ(A2;"*apple*");"Yes";"No") делает ту же проверку через СЧЁТЕСЛИ: количество 1 считается как ИСТИНА, а 0 как ЛОЖЬ.
Подсчёт ячеек с одним из нескольких слов
Если сложить две СЧЁТЕСЛИ, ячейка, где есть оба слова, посчитается дважды. Вместо этого проверяйте каждую ячейку один раз: ищите каждое слово через ПОИСК, складывайте результаты ИСТИНА и считайте строки, где сумма больше 0.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Formula | Count | |
| 2 | Apple | Two COUNTIFs | 5 | |
| 3 | Orange juice | Each cell once | 4 | |
| 4 | Pear | |||
| 5 | apple juice | |||
| 6 | Plum | |||
| 7 | Green apple |
=СЧЁТЕСЛИ(A2:A7;"*apple*")+СЧЁТЕСЛИ(A2:A7;"*juice*")Apple или juice упоминаются в четырёх товарах, но две СЧЁТЕСЛИ дают 5, потому что apple juice посчитан обеими. Вариант с СУММПРОИЗВ даёт 4.
Практика: посчитать текстовые ячейки
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Delivery | Weight | What | Count | |
| 2 | D-1 | 12 | Notes | ||
| 3 | D-2 | 9 | |||
| 4 | D-3 | damaged | |||
| 5 | D-4 | 15 | |||
| 6 | D-5 | missing | |||
| 7 | D-6 | ||||
| 8 | D-7 | late |
Ваша очередь: У одних доставок указан вес, у других заметка. Посчитайте ячейки в B2:B8, в которых стоит текст. Напишите формулу в E2.
Почему количество текстовых ячеек не сходится
- Числа, сохранённые как текст, считаются. В столбце, импортированном из другой системы, может стоять
'125как текст."*"его считает, а СЧЁТ нет. Если СЧЁТ по столбцу чисел меньше, чем СЧЁТЗ, часть из них текст; см. числа, сохранённые как текст. - Ячейки, которые только выглядят пустыми. Ячейка с пробелом это текст, и она считается. Используйте
=СУММПРОИЗВ(--(ДЛСТР(СЖПРОБЕЛЫ(A2:A8))>0)), чтобы посчитать ячейки с видимыми символами. - TRUE и FALSE не текст.
"*"их пропускает, как и значения ошибок вроде#Н/Д(#N/A). - СЧЁТЕСЛИ не учитывает регистр. Для подсчёта с учётом регистра используйте НАЙТИ внутри СУММПРОИЗВ, как во второй таблице.
Часто задаваемые вопросы
Как посчитать ячейки с любым текстом в Excel?
Используйте =СЧЁТЕСЛИ(A2:A8;"*"). Звёздочка подходит к любому тексту, поэтому формула считает все текстовые ячейки и пропускает числа, даты, ИСТИНА/ЛОЖЬ и пустые ячейки.
Как посчитать ячейки, содержащие определённый текст?
Поставьте звёздочки вокруг слова: =СЧЁТЕСЛИ(A2:A8;"*apple*") считает ячейки, где apple встречается в любом месте и в любом регистре. Без звёздочек "apple" считает только ячейки, где стоит ровно apple.
Как написать «если ячейка содержит текст, то» в Excel?
Соедините ЕСЛИ, ЕЧИСЛО и ПОИСК: =ЕСЛИ(ЕЧИСЛО(ПОИСК("apple";A2));"Yes";"No"). ПОИСК возвращает позицию, если находит текст, и ошибку, если не находит, а ЕЧИСЛО превращает это в ИСТИНА или ЛОЖЬ.
Как проверить, есть ли в ячейке вообще какой-то текст?
Используйте =ЕТЕКСТ(A2): она даёт ИСТИНА для текста и ЛОЖЬ для чисел, дат и пустых ячеек. Внутри ЕСЛИ: =ЕСЛИ(ЕТЕКСТ(A2);"Text";"Not text").
