=CHOOSE(B2,"Low","Medium","High") menghasilkan nilai di posisi yang ditentukan oleh B2: Low untuk 1, Medium untuk 2, High untuk 3. Argumen pertama adalah indeksnya, dan semua yang ada sesudahnya adalah daftar pilihannya.
| A | B | C | |
|---|---|---|---|
| 1 | Task | Priority | Label |
| 2 | Fix login | 3 | High |
| 3 | Update docs | 1 | Low |
| 4 | Review PR | 2 | Medium |
| 5 | Clean inbox | 1 | Low |
| 6 | Ship release | 3 | High |
Ubah sebuah prioritas menjadi 2 dan labelnya berubah menjadi Medium. Prioritas 4 menghasilkan #VALUE!, karena daftarnya hanya punya tiga nilai; begitu juga 0.
Sintaks CHOOSE
=CHOOSE(index_num, value1, [value2], ...)
index_num: angka dari 1 sampai jumlah nilainya (maksimal 254). Angka desimal dibulatkan ke bawah menjadi bilangan bulat, jadi 2,9 memilih nilai ke-2.value1, value2, ...: apa yang dikembalikan. Bisa berupa angka, teks, referensi sel, rumus, atau rentang utuh.
Nama hari dari sebuah tanggal
WEEKDAY menghasilkan angka dari 1 (Minggu) sampai 7 (Sabtu), dan itu persis indeks yang dibutuhkan CHOOSE.
| A | B | |
|---|---|---|
| 1 | Date | Day |
| 2 | 2026-03-02 | Mon |
| 3 | 2026-03-06 | Fri |
| 4 | 2026-03-07 | Sat |
| 5 | 2026-03-11 | Wed |
| 6 | 2026-03-15 | Sun |
2026-03-02 adalah hari Senin, jadi B2 menampilkan Mon. Edit sebuah tanggal dan namanya ikut berubah. =TEXT(A2,"ddd") memberikan nama singkat yang sama tanpa daftar (dibahas di halaman weekday). CHOOSE adalah pilihannya kalau kamu ingin label sendiri, seperti "Weekday" dan "Weekend", atau minggu yang dimulai dari hari lain.
CHOOSE sebagai pengganti IF bertingkat
Kalau kondisinya berupa nomor posisi, CHOOSE bisa menggantikan rangkaian IF. Kedua rumus di bawah menghasilkan tingkat pertumbuhan untuk nomor skenario di B1.
| A | B | |
|---|---|---|
| 1 | Scenario (1 to 3) | 2 |
| 2 | Growth (CHOOSE) | 5% |
| 3 | Growth (nested IF) | 5% |
| 4 | ||
| 5 | Sales this year | 120,000 |
| 6 | Sales next year | 126,000 |
Skenario 2 menghasilkan 5% dan penjualan tahun depan sebesar 126.000. Pilih 3 di B1 untuk 8%. Versi CHOOSE tetap satu tingkat berapa pun skenario yang kamu tambahkan; versi IF bertambah satu tingkat untuk setiap skenario. Kalau kondisinya berupa label teks, pakai SWITCH; untuk rentang nilai seperti 0 sampai 999, pakai tabel pencarian.
Memilih rentang utuh
Nilainya bisa berupa rentang, jadi CHOOSE bisa menentukan kolom mana yang dibaca SUM atau AVERAGE. Dengan penjualan Januari sampai Maret di B2:B5, C2:C5, dan D2:D5, serta nomor bulan di F2:
=SUM(CHOOSE(F2, B2:B5, C2:C5, D2:D5))
Dengan 3 di F2, rumus ini menjumlahkan D2:D5, yaitu kolom Maret. Kalau kolomnya lebih dari beberapa, menuliskan setiap rentang jadi panjang, dan INDEX bisa melakukan hal yang sama dengan satu rentang: =SUM(INDEX(B2:D5,0,F2)), dengan 0 berarti "semua baris" (dijelaskan di halaman INDEX). CHOOSE tetap berguna kalau rentangnya tidak bersebelahan, atau berada di lembar kerja yang berbeda.
CHOOSECOLS dan CHOOSEROWS
Microsoft 365 dan Excel 2024 menambahkan dua fungsi yang mengambil kolom atau baris utuh dari sebuah rentang berdasarkan nomor, lalu menampilkan hasilnya sebagai spill. Angka negatif dihitung dari akhir.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Product | Category | Price | Stock | Product | Stock | |
| 2 | Apple | Fruit | $1.20 | 40 | Apple | 40 | |
| 3 | Pear | Fruit | $1.50 | 25 | Pear | 25 | |
| 4 | Carrot | Vegetable | $0.80 | 60 | Carrot | 60 | |
| 5 | Bread | Bakery | $2.40 | 15 | Bread | 15 | |
| 6 | Milk | Dairy | $1.10 | 30 | Milk | 30 |
F1 menampilkan kolom Product dan Stock sebagai spill, termasuk header-nya. Nomornya boleh dalam urutan apa pun: =CHOOSECOLS(A1:D6,4,1) menaruh Stock sebelum Product. =CHOOSEROWS(A1:D6,1,-1) menghasilkan baris header dan baris terakhir.
Latihan: ongkos kirim berdasarkan metode
| A | B | C | |
|---|---|---|---|
| 1 | Order | Method | Cost |
| 2 | 1001 | 2 |
Giliranmu: Metode 1 biayanya 5, metode 2 biayanya 9, dan metode 3 biayanya 15. Di C2, pakai CHOOSE untuk menghasilkan biaya dari nomor metode di B2.
Pertanyaan yang sering diajukan
Apa fungsi CHOOSE di Excel?
CHOOSE menghasilkan salah satu nilai dari sebuah daftar berdasarkan angka: =CHOOSE(2,"Red","Green","Blue") menghasilkan Green. Argumen pertama memilih posisinya, dan nilai-nilai sesudahnya bisa berupa angka, teks, referensi sel, atau rentang.
Kenapa CHOOSE menghasilkan #VALUE!?
Indeksnya kurang dari 1 atau lebih besar dari jumlah nilainya. =CHOOSE(4,"Red","Green","Blue") hanya punya tiga nilai untuk dipilih. Indeks desimal dibulatkan ke bawah menjadi bilangan bulat, jadi 2,7 memilih nilai kedua.
Kapan sebaiknya memakai CHOOSE, bukan IF?
Saat kondisinya berupa nomor posisi seperti 1, 2, 3. =CHOOSE(B2,5,9,15) lebih pendek dan lebih mudah dibaca daripada =IF(B2=1,5,IF(B2=2,9,15)). Untuk kondisi yang bukan angka berurutan, pakai IFS, SWITCH, atau tabel pencarian.
Apa itu CHOOSECOLS di Excel?
Fungsi yang lebih baru untuk mengambil kolom tertentu dari sebuah rentang: =CHOOSECOLS(A1:D5,1,4) menghasilkan kolom pertama dan keempat. CHOOSEROWS melakukan hal yang sama untuk baris, dan angka negatif dihitung dari akhir. Keduanya butuh Microsoft 365 atau Excel 2024.
