Соперник на линии

Урок 13 из 20 курса Игра на Godot: Неоновый круг на Coddy.

Рядом с тобой стоит розовая машина. Это соперник, которому не нужно рулить: он едет по центральной линии трассы, немного в стороне от неё.

Храни пройденное им расстояние по трассе в progress и увеличивай его с максимальной скоростью. track.point_at(progress) — это точка на центральной линии, а direction_at — направление трассы в этой точке:

func place() -> void:
	var direction: Vector2 = track.direction_at(progress)
	position = track.point_at(progress) + direction.orthogonal() * lane
	rotation = direction.angle()

lane смещает машину с центральной линии на указанное количество пикселей, поэтому соперники могут ехать рядом друг с другом. Значение progress продолжает расти и после одного круга; point_at зацикливает его.

Задание

Легко

В rival.gd добавь экспорты top_speed := 200.0, lane := 0.0, start_offset := 40.0.
Добавь var progress := 0.0, var active := true и track с помощью @onready.
В _ready присвой progress = start_offset и вызови place().
В _physics_process выполни возврат, если active не является true, увеличь progress на top_speed * delta и вызови place().

Попробуйте сами

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO
var boost_time := 0.0
var boost_charge := 0.0
var active := true

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := 0.0
	var steer := 0.0
	if active:
		throttle = Input.get_axis("move_down", "move_up")
		steer = Input.get_axis("move_left", "move_right")
		if Input.is_action_just_pressed("action") and boost_charge >= 1.0:
			boost_charge = 0.0
			boost_time = 1.0
	boost_charge = minf(1.0, boost_charge + delta / 10.0)
	$"../HUD/Boost".scale.x = boost_charge

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	var grip_now := grip
	if boost_time > 0.0:
		boost_time -= delta
		top = max_speed * 1.3
		velocity += forward * accel * delta
	for pad in get_tree().get_nodes_in_group("boost_pads"):
		if position.distance_to(pad.position) < 22.0:
			boost_time = maxf(boost_time, 0.4)
	for oil in get_tree().get_nodes_in_group("oil"):
		if position.distance_to(oil.position) < 20.0:
			grip_now = grip * 0.12
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip_now * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0 or boost_time > 0.0
	$Flame.visible = boost_time > 0.0