Контрольные точки по порядку

Урок 9 из 20 курса Игра на Godot: Неоновый круг на Coddy.

В гонке нужны круги, и круг засчитывается, только если ты действительно проехал его полностью. Иначе можно пересечь линию, сдать назад и пересечь её снова. Поэтому на трассе есть 8 равномерно расположенных контрольных точек, которые нужно проезжать по порядку.

Логика гонки находится в race.gd, на узле Main. track.offset_of(point) показывает, насколько далеко по трассе находится точка: от 0 на линии старта до track.length. Контрольная точка k находится на расстоянии k * seg:

func check_progress() -> void:
	var seg: float = track.length / CHECKPOINTS
	var offset: float = track.offset_of(car.position)
	var target := next_checkpoint * seg
	var gap: float = absf(wrapf(offset - target, -track.length / 2.0, track.length / 2.0))
	if gap < 24.0 and track.is_on_road(car.position):
		next_checkpoint = (next_checkpoint + 1) % CHECKPOINTS

wrapf правильно вычисляет расстояние у линии старта, где 1390 и 5 разделяют всего 14 пикселей. Выражение % CHECKPOINTS направляет следующую после контрольной точки 7 к точке 0 — линии старта. Проверка is_on_road не даст засчитать срез через траву.

Задание

Средне

В race.gd добавь const CHECKPOINTS := 8 и var next_checkpoint := 1.
Получи track ($Track) и car ($Car) с помощью @onready.
Напиши check_progress и вызови её из _physics_process.

Попробуйте сами

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO
var boost_time := 0.0
var boost_charge := 0.0

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")
	if Input.is_action_just_pressed("action") and boost_charge >= 1.0:
		boost_charge = 0.0
		boost_time = 1.0
	boost_charge = minf(1.0, boost_charge + delta / 10.0)
	$"../HUD/Boost".scale.x = boost_charge

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	var grip_now := grip
	if boost_time > 0.0:
		boost_time -= delta
		top = max_speed * 1.3
		velocity += forward * accel * delta
	for pad in get_tree().get_nodes_in_group("boost_pads"):
		if position.distance_to(pad.position) < 22.0:
			boost_time = maxf(boost_time, 0.4)
	for oil in get_tree().get_nodes_in_group("oil"):
		if position.distance_to(oil.position) < 20.0:
			grip_now = grip * 0.12
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip_now * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0 or boost_time > 0.0
	$Flame.visible = boost_time > 0.0