CALL 和 RET
本课属于 Coddy Assembly 学习旅程的“函数、栈与字符串”单元。第 6 课,共 33 课。
过程是一段可以在程序中的多个位置运行的代码。在 Assembly 中,过程是一个标签,其代码以 ret 结束。call double 会运行 double 处的代码,而其中的 ret 会让程序返回到 call 后面的指令。
call 会通过将返回位置压入栈中来记住它。call double 会压入下一条指令的地址(返回地址),然后跳转到 double。
; rsp = 1000
call double ; 将返回地址压入栈中:rsp = 992
add rax, 1 ; 返回地址指向这里ret 会将该地址弹入 rip,也就是保存下一条指令地址的寄存器。程序会在 call 后面继续运行,并且 rsp 会恢复到原来的位置。
double:
add rax, rax
ret ; 弹出返回地址:rsp = 1000调用前,先把值放到过程所需的位置。这里,double 会将 rax 加倍,因此 solve 会先将输入复制到 rax 中:
solve:
mov rax, rdi
call double ; rax = rdi * 2
ret
double:
add rax, rax
ret你的 solve 也是一个过程。锁定的 main.asm 会运行 call solve;你的 ret 会返回到它,并输出 rax,所以每个 solve 都以 ret 结束。
挑战
简单编写一个过程 double,将 rax 中的值加倍,并将结果保存在 rax 中。solve 会通过 rdi 接收一个数字 n(-1000 到 1000):将它复制到 rax 中,调用两次 double,然后在 rax 中返回结果(n 的 4 倍)。
示例:输入 3 时,程序会打印 12。
在 solution.asm 中编写代码。锁定的 main.asm 会读取输入、调用 solve,并打印 rax 中的数字。
亲手试试
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall函数、栈与字符串中的所有课
自己练习: Assembly 在线编辑器