PUSH 和 POP
本课属于 Coddy Assembly 学习旅程的“函数、栈与字符串”单元。第 1 课,共 33 课。
栈是程序用来临时存储值的一块内存区域。寄存器 rsp(栈指针)保存着栈顶值的地址。程序启动时,rsp 已经指向栈内存。
push 会将一个 8 字节的值放到栈顶。push rdi 会先从 rsp 减去 8,然后将 rdi 存储到 rsp 中的新地址。栈向低地址增长:每次压入都会将 rsp 移到更低的地址。实际地址都是很大的数字,因此示例使用较小的数字。
; rsp = 1000
push rdi ; rsp = 992,rdi 存储在地址 992
push rsi ; rsp = 984,rsi 存储在地址 984pop 会取出栈顶的值。pop rax 会将地址 rsp 处的 8 个字节复制到 rax,然后将 rsp 加 8。
; rsp = 984
pop rax ; rax = 地址 984 处的值,rsp = 992
pop rbx ; rbx = 地址 992 处的值,rsp = 1000push 和 pop 可以在不使用第三个寄存器的情况下交换两个寄存器的值。第一次 pop 会返回最后一次 push 的值:
push rdi ; 保存 rdi
push rsi ; 把 rsi 保存在栈顶
pop rdi ; rdi = 原来的 rsi
pop rsi ; rsi = 原来的 rdi在本单元中,挑战会像 C 程序调用函数一样调用你的代码。锁定的 main.asm 会按顺序将输入放入 rdi、rsi、rdx 和 rcx,调用你的 solve,并输出你留在 rax 中的数字。每个任务都会说明会用到哪些输入。第 3 章会解释为什么使用这些寄存器。
挑战
简单solve 接收两个数字:第一个在 rdi 中,第二个在 rsi 中。使用两条 push 和两条 pop 指令交换这两个寄存器,然后在 rax 中返回 rdi - rsi。
示例:输入 3 10 时,程序会输出 7。
在 solution.asm 中编写代码。锁定的 main.asm 会读取输入、调用 solve,并输出 rax 中的数字。
亲手试试
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall函数、栈与字符串中的所有课
自己练习: Assembly 在线编辑器