Menu
CoddyTech

更改大小写

本课属于 Coddy Assembly 学习旅程的“函数、栈与字符串”单元。第 23 课,共 33 课。

小写字母 'a' 到 'z' 对应 97 到 122,大写字母 'A' 到 'Z' 对应 65 到 90。每个大写字母的数值都比对应的小写字母小 32:'a' 的 97 变为 'A' 的 65。

要将一个字节转换为大写字母,请检查它是否在 'a' 到 'z' 的范围内,然后减去 32。其他字节(大写字母、数字、空格)保持不变。

    cmp cl, 'a'
    jb .keep
    cmp cl, 'z'
    ja .keep
    sub cl, 32        ; 'h' 变成 'H'
.keep:

mov [rsi], cl 会将一个字节,也就是 rcx 的最低字节,写入 rsi 中的地址。写入的数据大小由寄存器决定:cl 是一个字节,因此会写入一个字节。

从本课开始,有些任务需要构建一段新文本。此时,solve 还会在 rsi 中接收一个空的 256 字节缓冲区的地址。将文本写入其中,并在 rax 中返回文本的长度;锁定的 main.asm 会打印缓冲区中的相应字节数。

一个索引可以同时遍历文本和缓冲区。这个循环会原样复制文本,最后 rax 的值就是文本的长度:

    xor eax, eax
.next:
    movzx ecx, byte [rdi + rax]
    test ecx, ecx
    jz .done
    mov [rsi + rax], cl
    inc rax
    jmp .next
.done:
challenge icon

挑战

简单

solve 接收文本的地址(位于 rdi 中),文本以一个零字节结尾;还接收一个空缓冲区的地址(位于 rsi 中)。将文本复制到缓冲区中,把每个小写字母 a 到 z 转换为大写字母,其他字节保持不变。将文本长度返回到 rax。

示例:输入 hello 时,程序会输出 HELLO。

在 solution.asm 中编写代码。锁定的 main.asm 会读取一行文本,调用 solve,并输出缓冲区的前 rax 个字节。

亲手试试

bits 64
section .data
    changed_rbx db 'solve changed rbx', 10
    changed_rbp db 'solve changed rbp', 10
    changed_r12 db 'solve changed r12', 10
    changed_r13 db 'solve changed r13', 10
    changed_r14 db 'solve changed r14', 10
    changed_r15 db 'solve changed r15', 10
section .bss
    input_buffer resb 257
    text_buffer resb 257
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jg .trim
    xor eax, eax
.trim:
    test rax, rax
    jz .ended
    movzx edx, byte [input_buffer + rax - 1]
    cmp dl, 10
    je .drop
    cmp dl, 13
    jne .ended
.drop:
    dec rax
    jmp .trim
.ended:
    mov byte [input_buffer + rax], 0
    mov rbx, 0x1111111111111111
    mov rbp, 0x2222222222222222
    mov r12, 0x3333333333333333
    mov r13, 0x4444444444444444
    mov r14, 0x5555555555555555
    mov r15, 0x6666666666666666
    lea rdi, [input_buffer]
    lea rsi, [text_buffer]
    xor eax, eax
    call solve
    mov rdx, 0x1111111111111111
    lea rsi, [changed_rbx]
    cmp rbx, rdx
    jne .changed
    mov rdx, 0x2222222222222222
    lea rsi, [changed_rbp]
    cmp rbp, rdx
    jne .changed
    mov rdx, 0x3333333333333333
    lea rsi, [changed_r12]
    cmp r12, rdx
    jne .changed
    mov rdx, 0x4444444444444444
    lea rsi, [changed_r13]
    cmp r13, rdx
    jne .changed
    mov rdx, 0x5555555555555555
    lea rsi, [changed_r14]
    cmp r14, rdx
    jne .changed
    mov rdx, 0x6666666666666666
    lea rsi, [changed_r15]
    cmp r15, rdx
    jne .changed
    cmp rax, 256
    jbe .length_ok
    mov eax, 256
.length_ok:
    mov byte [text_buffer + rax], 10
    lea rdx, [rax + 1]
    lea rsi, [text_buffer]
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall
.changed:
    mov eax, 1
    mov edi, 1
    mov edx, 18
    syscall
    jmp .exit

函数、栈与字符串中的所有课

自己练习: Assembly 在线编辑器