Menu
CoddyTech

返回值

本课属于 Coddy Assembly 学习旅程的“函数、栈与字符串”单元。第 12 课,共 33 课。

函数会将结果放在 rax 中返回。调用方会在 call 之后立即读取 rax,此时它还没有被其他操作改变。

编写自己的函数也遵循相同的规则:一个标签,从 rdi、rsi 和 rdx 读取参数的代码,并将结果放在 rax 中,然后执行 ret。

; sum3(rdi, rsi, rdx):返回 rdi + rsi + rdx
sum3:
    mov rax, rdi
    add rax, rsi
    add rax, rdx
    ret

当 solve 收到的参数正是它要继续传递的参数时,这些参数已经位于正确的寄存器中,因此它可以立即调用并使用结果:

solve:
    call sum3       ; rax = 三个输入的总和
    imul rax, rax, 2
    ret

以点开头的标签,例如 .done,属于它前面最近的一个不带点的标签。因此,两个函数可以各自拥有自己的 .done;用普通标签命名每个函数,例如 sum3。

rax 是结果寄存器,因此调用总会改变它,即使调用的是一个没有返回有用内容的函数。不要指望 rax 在 call 调用前后保持原值:先用 push 保存它。

challenge icon

挑战

简单

编写一个函数 clamp:值位于 rdi,下限位于 rsi,上限位于 rdx(范围均为 -1000 到 1000,下限不会高于上限)。它将值返回到 rax 中;如果值超出范围,则提高到下限或降低到上限。solve 会在 rdi、rsi 和 rdx 中接收相同的三个数字:调用 clamp,并将其结果乘以 2 后返回到 rax 中。

示例:输入 5 1 10 时,程序会输出 10。

在 solution.asm 中编写代码。锁定的 main.asm 会读取输入、调用 solve,并输出 rax 中的数字,或者输出被 solve 修改的被调用者保存寄存器的名称。

亲手试试

bits 64
section .data
    changed_rbx db 'solve changed rbx', 10
    changed_rbp db 'solve changed rbp', 10
    changed_r12 db 'solve changed r12', 10
    changed_r13 db 'solve changed r13', 10
    changed_r14 db 'solve changed r14', 10
    changed_r15 db 'solve changed r15', 10
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rbx, 0x1111111111111111
    mov rbp, 0x2222222222222222
    mov r12, 0x3333333333333333
    mov r13, 0x4444444444444444
    mov r14, 0x5555555555555555
    mov r15, 0x6666666666666666
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    mov rdx, 0x1111111111111111
    lea rsi, [changed_rbx]
    cmp rbx, rdx
    jne .changed
    mov rdx, 0x2222222222222222
    lea rsi, [changed_rbp]
    cmp rbp, rdx
    jne .changed
    mov rdx, 0x3333333333333333
    lea rsi, [changed_r12]
    cmp r12, rdx
    jne .changed
    mov rdx, 0x4444444444444444
    lea rsi, [changed_r13]
    cmp r13, rdx
    jne .changed
    mov rdx, 0x5555555555555555
    lea rsi, [changed_r14]
    cmp r14, rdx
    jne .changed
    mov rdx, 0x6666666666666666
    lea rsi, [changed_r15]
    cmp r15, rdx
    jne .changed
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall
.changed:
    mov eax, 1
    mov edi, 1
    mov edx, 18
    syscall
    jmp .exit

函数、栈与字符串中的所有课

自己练习: Assembly 在线编辑器