Menu
CoddyTech

递归

本课属于 Coddy Assembly 学习旅程的“函数、栈与字符串”单元。第 18 课,共 33 课。

递归函数会针对更小的问题调用自身。n 的阶乘等于 n 乘以 n - 1 的阶乘:4! = 4 * 3!。递归链会在 1! = 1 时停止,而且 0! = 1 也是如此。

每个递归函数都需要一个基本情况:遇到这种输入时,函数会直接给出答案,而不调用自身。如果没有基本情况,函数调用就不会停止。每次调用都会压入一个返回地址,直到栈空间耗尽,程序崩溃。

factorial 接收 rdi 中的 n,并在 rax 中返回 n!:

factorial:
    cmp rdi, 1
    jg .recurse
    mov eax, 1
    ret
.recurse:
    push rdi
    dec rdi
    call factorial
    pop rdi
    imul rax, rdi
    ret

内部调用会改变 rdi,因此每次调用都会在调用前将自己的 n 压入栈中,并在调用后将其弹出。每次调用在栈上都有自己的返回地址和保存的 n。

对于 factorial(3):它保存 3 并调用 factorial(2),后者保存 2 并调用 factorial(1),后者返回 1。然后,返回值按相反的顺序处理:2 * 1 = 2,接着 3 * 2 = 6。

challenge icon

挑战

简单

编写一个递归函数 factorial:n 位于 rdi 中(范围为 0 到 20),n! 位于 rax 中,0! 和 1! 都等于 1。solve 接收位于 rdi 中的 n,调用 factorial,并在 rax 中返回结果。

示例:输入 5 时,程序会输出 120。

在 solution.asm 中编写代码。锁定的 main.asm 会读取输入、调用 solve,并输出 rax 中的数字,或者被 solve 修改的某个被调用者保存寄存器的名称。

亲手试试

bits 64
section .data
    changed_rbx db 'solve changed rbx', 10
    changed_rbp db 'solve changed rbp', 10
    changed_r12 db 'solve changed r12', 10
    changed_r13 db 'solve changed r13', 10
    changed_r14 db 'solve changed r14', 10
    changed_r15 db 'solve changed r15', 10
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rbx, 0x1111111111111111
    mov rbp, 0x2222222222222222
    mov r12, 0x3333333333333333
    mov r13, 0x4444444444444444
    mov r14, 0x5555555555555555
    mov r15, 0x6666666666666666
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    mov rdx, 0x1111111111111111
    lea rsi, [changed_rbx]
    cmp rbx, rdx
    jne .changed
    mov rdx, 0x2222222222222222
    lea rsi, [changed_rbp]
    cmp rbp, rdx
    jne .changed
    mov rdx, 0x3333333333333333
    lea rsi, [changed_r12]
    cmp r12, rdx
    jne .changed
    mov rdx, 0x4444444444444444
    lea rsi, [changed_r13]
    cmp r13, rdx
    jne .changed
    mov rdx, 0x5555555555555555
    lea rsi, [changed_r14]
    cmp r14, rdx
    jne .changed
    mov rdx, 0x6666666666666666
    lea rsi, [changed_r15]
    cmp r15, rdx
    jne .changed
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall
.changed:
    mov eax, 1
    mov edi, 1
    mov edx, 18
    syscall
    jmp .exit

函数、栈与字符串中的所有课

自己练习: Assembly 在线编辑器