被调用者保存寄存器
本课属于 Coddy Assembly 学习旅程的“函数、栈与字符串”单元。第 14 课,共 33 课。
这条规则的另一半是:rbx、rbp 和 r12 到 r15 是被调用者保存的寄存器。使用其中一个寄存器的函数必须在执行 ret 之前恢复它的旧值。作为回报,这些寄存器中的值在每次函数调用后都会保留。
因此,必须在一次调用结束后仍保留的值应放在被调用者保存寄存器中。调用 score 的循环可以将计数器保存在 rbx 中,并将总数保存在 r12 中,而 score 不会改动这两个寄存器。
mov rdi, rbx ; 要计算分数的关卡
call score ; rbx 和 r12 保持不变
add r12, rax你的 solve 也是一个函数:main.asm 可以在 rbx 和 r12 中保留自己的值。在 solve 开始时保存它们,并在结束时按相反顺序恢复:
solve:
push rbx
push r12
; ... 使用 rbx 和 r12 ...
pop r12
pop rbx
ret在本章中,main.asm 会检查这条规则。它会在调用 solve 之前,将已知值放入 rbx、rbp 和 r12 到 r15,并在调用后进行比较。如果其中一个值发生了变化,它会输出类似 solve changed rbx 的一行内容,而不是你的答案。
rsp 也必须恢复原样。每次 push 都有对应的 pop,这样你就能恢复它,否则测试框架会在执行你的 ret 时崩溃。
挑战
简单solve 在 rdi 中接收一个数字 n(1 到 50)。对从 1 到 n 的每个等级 i,调用 score,并将等级放在 rdi 中,然后在 rax 中返回所有 score(i) 的总和。将计数器保存在 rbx 中,将总和保存在 r12 中:在 solve 开始时压入这两个寄存器,并在 ret 前按相反顺序弹出它们。
示例:输入 1 时,程序会输出 4。
在 solution.asm 中编写代码。锁定的 main.asm 会读取输入、调用 solve 并输出 rax 中的数字,或者输出 solve 修改过的被调用者保存寄存器的名称。
lib.asm 中包含 max2、area、score 和 points,每个函数都有一条注释;该文件已锁定。
亲手试试
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exit函数、栈与字符串中的所有课
自己练习: Assembly 在线编辑器