使用 RBP 的栈帧
本课属于 Coddy Assembly 学习旅程的“函数、栈与字符串”单元。第 17 课,共 33 课。
由于局部变量、压栈和调用会让 rsp 不断移动,因此 [rsp + 8] 在函数的不同位置可能指向不同的槽位。栈帧提供了一个固定的测量基准:寄存器 rbp(基址指针)。
带有栈帧的函数以三行代码开头,这部分称为序言:
push rbp ; 保存调用方的 rbp
mov rbp, rsp ; rbp 标记当前栈帧
sub rsp, 16 ; 两个局部变量局部变量位于 rbp 下方,地址分别为 [rbp - 8] 和 [rbp - 16]。无论之后压入多少个值,这些地址在整个函数中都指向相同的存储位置。
尾声会撤销序言中的操作。mov rsp, rbp 会一次性丢弃所有局部变量,而 pop rbp 会把调用者的 rbp 还回去:
mov rsp, rbp ; 丢弃局部变量
pop rbp ; 恢复调用方的 rbp
retrbp 是被调用者保存寄存器,因此开头的压栈和结尾的出栈会让它对调用者保持不变。rbp 上方是保存在 [rbp] 处的 rbp 和保存在 [rbp + 8] 处的返回地址。你使用的其他被调用者保存寄存器,应在序言之后立即压入栈中,并在 mov rsp, rbp 之前立即出栈:
push rbp
mov rbp, rsp
sub rsp, 16
push rbx
; ... 函数 ...
pop rbx
mov rsp, rbp
pop rbp
ret挑战
简单solve 会接收 rdi 中的 n(1 到 50)。使用一个包含两个局部变量的栈帧:用 [rbp - 8] 保存目前为止见过的最高 score,用 [rbp - 16] 保存对应的等级。检查从 1 到 n 的等级,并保留得分最高的第一个等级。在 rax 中返回 level * 100 + score。
示例:输入 5 时,程序会输出 509。
在 solution.asm 中编写代码。锁定的 main.asm 会读取输入、调用 solve,并输出 rax 中的数字,或者输出 solve 修改过的被调用者保存寄存器的名称。
lib.asm 中包含 max2、area、score 和 points,每个函数都有一条注释。该文件已锁定。
亲手试试
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exit这节课包含一个小测验。开始学习即可作答,并记录你的进度。
函数、栈与字符串中的所有课
自己练习: Assembly 在线编辑器