使用 [rsp] 读取
本课属于 Coddy Assembly 学习旅程的“函数、栈与字符串”单元。第 4 课,共 33 课。
rsp 保存着一个地址,因此你可以像读取其他内存一样读取栈。mov rax, [rsp] 会将栈顶的值复制到 rax,但不会将其弹出:rsp 保持不变。
每个槽位占 8 字节,较早压入的值位于更高的地址。压入 10、20 和 30 后:
push 10
push 20
push 30
mov rax, [rsp] ; rax = 30,位于栈顶
mov rbx, [rsp + 8] ; rbx = 20
mov rcx, [rsp + 16] ; rcx = 10,最先入栈读取不会移除任何内容。完成后,要把空间还回去:弹出每个值,或者用 add rsp, 24 一次性释放所有值(3 个值,每个 8 字节)。
栈必须在执行 ret 之前保持平衡。solve 以 ret 结束,它会从 [rsp] 中读取要返回的地址。如果你压入的值仍在栈顶,ret 就会把它当作地址使用,程序会在打印任何内容之前崩溃。
挑战
简单solve 会通过 rdi、rsi、rdx 和 rcx 接收四个数字。按这个顺序将它们压入栈中。不要弹出它们,使用 [rsp + ...] 读取从栈顶数第二个值和栈底的值(第一个压入的值),并将它们的和放入 rax 返回。在执行 ret 之前,移除全部四个值。
示例:输入为 1 2 3 4 时,程序会输出 4。
将代码写入 solution.asm。锁定的 main.asm 会读取输入、调用 solve,并输出 rax 中的数字。
亲手试试
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall这节课包含一个小测验。开始学习即可作答,并记录你的进度。
函数、栈与字符串中的所有课
自己练习: Assembly 在线编辑器