按顺序通过检查点

Coddy Godot 游戏：霓虹赛道课程的第 9 课，共 20 课。

比赛需要跑完若干圈，而且只有真正绕赛道跑完一圈才算数。否则，你可以冲过终点线，再倒车回来又冲过去。赛道上因此设置了 8 个等距分布的检查点，你必须按顺序通过它们。

比赛逻辑写在 Main 节点的 race.gd 中。track.offset_of(point) 会告诉你某个点沿赛道绕行的距离，从终点线处的 0 到 track.length。第 k 个检查点位于 k * seg 处：

func check_progress() -> void:
	var seg: float = track.length / CHECKPOINTS
	var offset: float = track.offset_of(car.position)
	var target := next_checkpoint * seg
	var gap: float = absf(wrapf(offset - target, -track.length / 2.0, track.length / 2.0))
	if gap < 24.0 and track.is_on_road(car.position):
		next_checkpoint = (next_checkpoint + 1) % CHECKPOINTS

wrapf 会让终点线附近的间距计算保持准确，因为 1390 和 5 只相距 14 像素。% CHECKPOINTS 会让检查点 7 的下一个检查点回到 0，也就是终点线。检查 is_on_road，可以确保抄近路穿过草地不算数。

挑战

中等

让比赛按顺序统计检查点。

在 race.gd 中添加 const CHECKPOINTS := 8 和 var next_checkpoint := 1。
使用 @onready 获取 track（$Track）和 car（$Car）。
编写 check_progress，并从 _physics_process 中调用它。

按下“开始”并绕圈驾驶：目前还不会显示任何新内容，下一课会介绍圈数。然后点击“检查”。

亲手试试

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO
var boost_time := 0.0
var boost_charge := 0.0

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")
	if Input.is_action_just_pressed("action") and boost_charge >= 1.0:
		boost_charge = 0.0
		boost_time = 1.0
	boost_charge = minf(1.0, boost_charge + delta / 10.0)
	$"../HUD/Boost".scale.x = boost_charge

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	var grip_now := grip
	if boost_time > 0.0:
		boost_time -= delta
		top = max_speed * 1.3
		velocity += forward * accel * delta
	for pad in get_tree().get_nodes_in_group("boost_pads"):
		if position.distance_to(pad.position) < 22.0:
			boost_time = maxf(boost_time, 0.4)
	for oil in get_tree().get_nodes_in_group("oil"):
		if position.distance_to(oil.position) < 20.0:
			grip_now = grip * 0.12
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip_now * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0 or boost_time > 0.0
	$Flame.visible = boost_time > 0.0