抓地与漂移

Coddy Godot 游戏：霓虹赛道课程的第 4 课，共 20 课。

急转弯时，汽车会像冰球一样打滑：车头指向一个方向，车却朝另一个方向移动。轮胎能防止这种情况。它们让汽车向前滚动，但不会横向滑动。

forward.orthogonal() 指向汽车侧面。把速度分解为沿着这个方向的部分，并在每一帧中消去其中的大部分：

var side := forward.orthogonal()
velocity -= side * velocity.dot(side) * minf(1.0, grip * delta)

当 grip 为 7 时，转弯后汽车会稍微延迟才跟着车头转向，并产生短暂的漂移。降低抓地力，漂移时间就会更长。minf(1.0, ...) 可以确保每一帧消去的横向部分不会超过其全部。

挑战

简单

让轮胎抓地，这样汽车就不会向侧面打滑。

添加 @export var grip := 7.0。
转向后，添加上面的两行 side 代码。
要观察长时间漂移，请在 car.gd 中将 grip 改为 2.0，然后按“开始”；在按“检查”前将其改回 7.0。

按“开始”并驶过弯道：短暂漂移后，汽车会朝车头指向的方向行驶。然后按“检查”。

亲手试试

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6

var velocity := Vector2.ZERO


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)
	velocity *= 1.0 - drag * delta
	velocity = velocity.limit_length(max_speed)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0