沿着道路行驶

Coddy Godot 游戏：霓虹赛道课程的第 5 课，共 20 课。

赛道由 track.gd 绘制，它也能回答有关赛道的问题。当一个点在路面上时，track.is_on_road(position) 的值为 true。离开路面后，汽车应该在草地上缓慢行驶。

汽车准备就绪时，获取一次赛道节点：

@onready var track: Node2D = $"../Track"

然后为这一帧设置最高速度。离开路面时，最高速度为 max_speed 的 45 percent，草地也会让汽车减速：

var top := max_speed
if not track.is_on_road(position):
	top = max_speed * 0.45
	velocity *= 1.0 - 2.5 * delta

最后，替换 limit_length。如果直接把速度骤降，汽车会在路边突然停下，所以要让速度平缓地降到最高速度：

if velocity.length() > top:
	velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)

挑战

简单

让草地减慢汽车的速度。

添加用于 track 的 @onready 行。
在 speed 后面，添加 var top := max_speed 和上面的越野路段代码块。
用上面的两行替换 limit_length 那一行。

按下“开始”，开上草地：汽车会慢慢行驶。然后点击“检查”。

亲手试试

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip * delta)
	velocity *= 1.0 - drag * delta
	velocity = velocity.limit_length(max_speed)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0