Voto medio

Fa parte della sezione Logica e flusso del percorso GDScript di Coddy. Lezione 46 di 78.

Sfida

Facile

Calcola il voto medio di uno studente. Mantieni tutto ciò che hai scritto nei passaggi precedenti.

1. La funzione. Sotto le altre funzioni, scrivi calculate_average_grade(student_name: String) -> float:

Se student_records non contiene il nome, stampa Student '<name>' not found. e restituisci -1.0. Nessuna media reale è negativa, quindi chi chiama la funzione può capire che lo studente non è stato trovato.
Se lo studente non ha ancora voti, restituisci 0.0.
Altrimenti restituisci la somma dei voti divisa per il loro numero, come float.

2. Il comando. Aggiungi questo ramo per average <name> prima di ["show"]. Stampa la media con due decimali, a meno che lo studente non sia stato trovato:

["average", var student]:
	var average := calculate_average_grade(student)
	if average >= 0:
		print("Average grade of '%s': %.2f" % [student, average])

Per i comandi

add Alice 20 Math Physics
add Bob 22 Biology Chemistry
grade Alice 90
grade Alice 85
grade Bob 75
average Alice
average Bob
average Charlie
exit

l'output è:

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Grade 90 added for student 'Alice'.
Grade 85 added for student 'Alice'.
Grade 75 added for student 'Bob'.
Average grade of 'Alice': 87.50
Average grade of 'Bob': 75.00
Student 'Charlie' not found.
Goodbye!

Provalo tu

extends Node

# Ogni studente: nome -> {"age": int, "grades": Array, "courses": un insieme di nomi di corsi}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)