Excel 中增长百分比的公式是 =(新值-旧值)/旧值。去年的值在 B2、今年的值在 C2 时，输入 =(C2-B2)/B2，并把单元格设置为百分比格式。结果为正表示增长，为负表示下降。
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Last year | This year | Change |
| 2 | Coffee | $12,400 | $14,880 | 20.0% |
| 3 | Tea | $8,600 | $7,740 | -10.0% |
| 4 | Juice | $5,200 | $5,460 | 5.0% |
| 5 | Water | $3,100 | $4,650 | 50.0% |
Coffee 增长了 20.0%，Tea 下降了 10.0%，显示为 -10.0%。Water 增长了 50.0%。改一下 C 列中的数字，百分比就会随之更新。括号很重要：没有括号时，=C2-B2/B2 会先做除法，变成今年的销售额减 1。
同一个公式的两种写法
=(C2-B2)/B2 the change divided by the old value
=C2/B2-1 the new value as a share of the old, minus 100%
两者结果相同。第一种读起来就是定义本身，以后检查更容易。无论哪种写法，除数永远是旧值。除以新值是最常见的错误，得到的是另一个数字：从 80 到 100 是 +25%，但 20 除以 100 是 20%。
如果两个数都不是旧值，比如并排比较两家门店，就改为用差额除以两者的平均值。这叫百分比差异，对于 80 和 100，不论谁在前都得到 22.2%：
=ABS(B2-C2)/AVERAGE(B2,C2)
环比百分比变化
对按时间排列的列表，把每一行和上一行比较。第一个月没有可比较的对象，所以公式从第二行开始。
| A | B | C | |
|---|---|---|---|
| 1 | Month | Visitors | Change |
| 2 | Jan | 4200 | |
| 3 | Feb | 4620 | 10.0% |
| 4 | Mar | 4389 | -5.0% |
| 5 | Apr | 5047 | 15.0% |
| 6 | May | 4795 | -5.0% |
| 7 | Jun | 5754 | 20.0% |
2 月比 1 月增长 10.0%，3 月下降 5.0%。如果想让每个月都和 1 月比较，用美元符号锁定基数：=(B3-$B$2)/$B$2。绝对引用讲解了 $。
从零开始的百分比变化
旧值为 0 时，公式会除以零并返回 #DIV/0!。从无到有的增长没有百分比，所以先决定单元格应显示什么，再加判断：
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Product | Last year | This year | Plain | Checked |
| 2 | Coffee | 12400 | 14880 | 20.0% | 20.0% |
| 3 | Cocoa | 0 | 2100 | #DIV/0! | new |
| 4 | Soda | 0 | 640 | #DIV/0! | new |
D3 和 D4 显示 #DIV/0!；加了判断的那一列显示“new”。这里 =IFERROR((C2-B2)/B2,"new") 结果相同，但它也会掩盖真正的错误，比如销售额列中混入了文本。除以零错误一文有更全面的介绍。
练习：写出百分比变化
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Item | Old price | New price | Change |
| 2 | Bread | $2.40 | $2.76 |
轮到你了： 在 D2 中计算从 B2 的旧价格到 C2 的新价格的百分比变化。单元格已经设置为百分比格式。
百分比变化与百分点
当数值本身就是百分比时，两个不同的答案都被叫作“变化”。转化率从 4% 升到 5%，上升了 1 个百分点，也上升了 25%。
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Page | Before | After | Points | Percent change |
| 2 | Signup | 4.0% | 5.0% | 1.0% | 25.0% |
D2 把两个比率相减，显示 1.0%，汇报时应说“1 个百分点”。E2 显示 25.0%。要说清楚指的是哪一个，因为“比率上升了 1%”两种意思都可能。
旧值为负数
旧值为负数时，比如由亏损转为盈利，普通公式给出的符号是错的：从 -200 到 100，=(C2-B2)/B2 返回 -150%。改为除以旧值的绝对值：
=(C2-B2)/ABS(B2)
从 -200 到 100，这样返回 150%，即增长。对于跨越多年的增长，每年的平均增长率比一个大的百分比更有用：=(C2/B2)^(1/5)-1 把五年的变化换算成复合年增长率（CAGR）。
常见问题
Excel 中增长百分比的公式是什么？
=(C2-B2)/B2，B2 是旧值，C2 是新值，单元格设置为百分比格式。=C2/B2-1 结果相同。从 80 到 100，结果是 25%。
Excel 中如何计算下降百分比？
用同一个公式 =(C2-B2)/B2。新值更小时结果为负数：从 100 到 80 是 -20%。Excel 没有单独的下降公式。
旧值为 0 时如何计算百分比变化？
从 0 开始的变化没有百分比，=(C2-B2)/B2 会返回 #DIV/0!。这种情况下显示别的内容：=IF(B2=0,"n/a",(C2-B2)/B2)。
有负数时如何计算百分比变化？
除以旧值的绝对值：=(C2-B2)/ABS(B2)。这样，从亏损 -200 变为盈利 100 会显示 +150%，即增长，而不是普通公式给出的误导性的 -150%。
