Recursão
Parte da seção Funções, pilha e strings do Journey de Assembly da Coddy. Lição 18 de 33.
Uma função recursiva chama a si mesma em uma versão menor do problema. O fatorial de n é n vezes o fatorial de n - 1: 4! = 4 * 3!. A cadeia termina em 1! = 1, e 0! = 1 também.
Toda função recursiva precisa de um caso-base: uma entrada para a qual ela fornece uma resposta sem chamar a si mesma. Sem ele, as chamadas nunca param. Cada chamada empilha um endereço de retorno, e a pilha fica sem espaço até o programa travar.
factorial recebe n em rdi e retorna n! em rax:
factorial:
cmp rdi, 1
jg .recurse
mov eax, 1
ret
.recurse:
push rdi
dec rdi
call factorial
pop rdi
imul rax, rdi
retA chamada interna altera rdi, então cada chamada empilha seu próprio n antes de chamar e o desempilha depois. Cada chamada tem seu próprio endereço de retorno e seu próprio n salvo na pilha.
Para factorial(3): ela salva 3 e chama factorial(2), que salva 2 e chama factorial(1), que retorna 1. Em seguida, os retornos são executados na ordem inversa: 2 * 1 = 2 e, depois, 3 * 2 = 6.
Desafio
FácilEscreva uma função recursiva factorial: n em rdi (0 a 20), n! em rax, com 0! e 1! iguais a 1. solve recebe n em rdi, chama factorial e retorna o resultado em rax.
Exemplo: para a entrada 5, o programa imprime 120.
Escreva seu código em solution.asm. O main.asm bloqueado lê a entrada, chama solve e imprime o número em rax ou o nome de um registrador preservado pelo chamador que solve alterou.
Experimente você mesmo
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitTodas as lições de Funções, pilha e strings
1A pilha
PUSH e POPÚltimo a entrar, primeiro a sairSalvando um registradorLendo com [rsp]Revisão: histórico de desfazer4Quadros de Pilha e Recursão
Variáveis locaisQuadros com RBPRecursãoDuas chamadas recursivasRevisão: soma dos dígitosPratique por conta própria: Playground de Assembly