Texto para número
Parte da seção Funções, pilha e strings do Journey de Assembly da Coddy. Lição 24 de 33.
O texto 472 tem três bytes: 52, 55 e 50, os códigos de '4', '7' e '2'. Ainda não é o número 472. Subtrair '0' (48) de um byte de dígito fornece seu valor: '7' menos '0' é 7.
Construa o número da esquerda para a direita: multiplique o que você tem por 10 e some o próximo dígito. Para 472: 0 vezes 10 mais 4 é 4, 4 vezes 10 mais 7 é 47, 47 vezes 10 mais 2 é 472.
As mesmas etapas em um loop sobre o texto:
xor eax, eax ; n = 0
.next:
movzx ecx, byte [rdi]
test ecx, ecx
jz .done
sub ecx, '0' ; o valor do dígito
imul rax, rax, 10
add rax, rcx ; n = n * 10 + digit
inc rdi
jmp .next
.done:O arquivo main.asm bloqueado dos capítulos 1 a 4 executa esse loop com sua entrada. É assim que o texto 3 10 se tornou os números 3 e 10 em rdi e rsi; ele também ignora os espaços e lida com um sinal de menos.
O loop presume que cada byte é um dígito. Uma letra ou um espaço adicionaria um valor incorreto, então o código que lê texto de uma pessoa verifica primeiro o intervalo de '0' a '9'.
Desafio
Fácilsolve recebe o endereço de um texto com 1 a 18 dígitos em rdi, terminado com um byte zero. Transforme os dígitos no número que eles representam e retorne esse número mais 1 em rax.
Exemplo: para a entrada 472, o programa imprime 473.
Escreva seu código em solution.asm. O main.asm bloqueado lê uma linha de texto, chama solve e imprime o número em rax.
Experimente você mesmo
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 257
text_buffer resb 256
output_buffer resb 32
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jg .trim
xor eax, eax
.trim:
test rax, rax
jz .ended
movzx edx, byte [input_buffer + rax - 1]
cmp dl, 10
je .drop
cmp dl, 13
jne .ended
.drop:
dec rax
jmp .trim
.ended:
mov byte [input_buffer + rax], 0
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
lea rdi, [input_buffer]
lea rsi, [text_buffer]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitEsta lição inclui um quiz rápido. Comece a lição para respondê-lo e acompanhar seu progresso.
Todas as lições de Funções, pilha e strings
1A pilha
PUSH e POPÚltimo a entrar, primeiro a sairSalvando um registradorLendo com [rsp]Revisão: histórico de desfazer4Quadros de Pilha e Recursão
Variáveis locaisQuadros com RBPRecursãoDuas chamadas recursivasRevisão: soma dos dígitosPratique por conta própria: Playground de Assembly