Konstruktor (_init)

Menetapkan setiap property setelah new() membutuhkan beberapa baris, dan kamu bisa dengan mudah melupakan salah satunya. Constructor menyiapkan object saat dibuat. Di GDScript, constructor adalah method _init():

# book.gd
class_name Book
extends RefCounted

var title: String
var author: String
var pages: int

func _init(book_title: String, book_author: String, page_count: int) -> void:
	title = book_title
	author = book_author
	pages = page_count

Argumen yang kamu berikan ke new() diteruskan ke _init(), yang berjalan otomatis sebelum new() mengembalikan object:

var dune := Book.new("Dune", "Frank Herbert", 412)
print(dune.title) # Dune
print(dune.pages) # 412

Ketika _init() memiliki parameter, new() harus meneruskannya: Book.new() tanpa argumen akan menyebabkan error yang dilaporkan sebelum program dijalankan. Parameter dengan nilai default bersifat opsional:

func _init(book_title: String, book_author: String = "Unknown") -> void:

Dengan constructor ini, Book.new("Notes") membuat buku yang author-nya "Unknown".

Nama parameter di atas berbeda dari nama property. Jika namanya sama, kamu akan menulis self.title = title, seperti dalam pelajaran tentang self.