Apa itu Sinyal?

Berbagai hal terjadi pada object saat game berjalan: sebuah koin dikumpulkan, sebuah pintu terbuka, hp hero turun menjadi 0. Bagian lain dari program bereaksi terhadap peristiwa ini: skor bertambah, suara diputar, layar game over muncul.

Sinyal adalah pesan yang dikirim object saat sesuatu terjadi padanya. Object mengirimkan sinyal tersebut, dan setiap fungsi yang terhubung ke sinyal itu akan dijalankan:

# coin.gd
class_name Coin
extends RefCounted

signal collected

func collect() -> void:
	print("Coin picked up")
	collected.emit()

signal collected mendeklarasikan sinyal dan collected.emit() mengirimkannya. Koin tidak tahu siapa yang mendengarkan. Kode yang membutuhkan koin menghubungkan salah satu fungsinya sendiri ke sinyal tersebut:

# main.gd
func _ready():
	var coin := Coin.new()
	coin.collected.connect(_on_coin_collected)
	coin.collect()
	print("Done")

func _on_coin_collected() -> void:
	print("Score +1")

Output-nya adalah Coin picked up, Score +1, Done. Pemancaran langsung menjalankan fungsi yang terhubung, sebelum baris setelah emit(). Sinyal tanpa fungsi yang terhubung tidak melakukan apa pun saat dipancarkan.

Tanpa signal, collect() harus memanggil kode skor itu sendiri, sehingga setiap koin perlu memiliki referensi ke papan skor. Dengan signal, koin hanya mengumumkan peristiwa tersebut, lalu berapa pun jumlah pendengar, atau tidak ada sama sekali, dapat meresponsnya.

Node bawaan Godot bekerja dengan cara yang sama: Button mengeluarkan pressed saat diklik, dan Timer mengeluarkan timeout saat waktunya habis.