Pengantar Virtual Method

Python memiliki magic method seperti __init__ dan __str__, yang dipanggil oleh bahasa tersebut untukmu. Versi Godot adalah virtual method: method dengan nama tetap yang diawali garis bawah, yang kamu definisikan di class-mu dan dipanggil Godot pada saat yang tepat. Kamu sudah menggunakan dua di antaranya:

• _init() dijalankan saat new() membuat object, dengan argumen yang diberikan ke new().
• _ready() dijalankan saat node memasuki scene tree, tempat main.gd dimulai.

Contoh lainnya adalah _to_string(), yang dipanggil saat sebuah object dicetak, method iterator yang memungkinkan perulangan for menelusuri sebuah object (keduanya dibahas dalam pelajaran berikutnya), dan _notification(), yang menerima event dari engine. Salah satunya, NOTIFICATION_PREDELETE, muncul tepat sebelum object dihapus:

# torch.gd
class_name Torch
extends RefCounted

var label: String

func _init(new_label: String = "Torch") -> void:
	label = new_label
	print(label, " lit")

func _notification(what: int) -> void:
	if what == NOTIFICATION_PREDELETE:
		print(label, " burned out")

# main.gd
var torch := Torch.new("Hall torch") # Hall torch menyala
torch = null # Hall torch padam

Object RefCounted dihapus segera setelah tidak ada lagi variabel yang merujuk kepadanya, jadi torch = null langsung mengirimkan pemberitahuan. Nilai default di _init() membuat argumen new() bersifat opsional: Torch.new() membuat obor bernama Torch.

Python juga menggunakan method ajaib untuk operator, seperti __add__ untuk + dan __eq__ untuk ==. GDScript tidak mendukung overloading operator: potion_a + potion_b adalah error. Tulis method sebagai gantinya:

# potion.gd
class_name Potion
extends RefCounted

var power: int

func _init(start_power: int) -> void:
	power = start_power

func combined(other: Potion) -> Potion:
	return Potion.new(power + other.power)

potion_a.combined(potion_b) mengembalikan potion baru dan membiarkan kedua potion asli tetap tidak berubah. == di antara dua object memeriksa apakah kedua sisi adalah object yang sama, bukan apakah nilainya cocok: Potion.new(5) == Potion.new(5) menghasilkan false. Tulis method seperti equals(other) saat kamu perlu membandingkan nilai.