Menu
CoddyTech

CALL e RET

Fa parte della sezione Funzioni, stack e stringhe del percorso Assembly di Coddy. Lezione 6 di 33.

Una procedura è codice che puoi eseguire da più punti di un programma. In Assembly è un’etichetta il cui codice termina con ret. call double esegue il codice in corrispondenza di double e il suo ret riporta il programma all’istruzione successiva a call.

call ricorda dove tornare inserendolo nello stack. call double inserisce nello stack l'indirizzo dell'istruzione successiva (l'indirizzo di ritorno), quindi esegue un salto a double.

; rsp = 1000
call double     ; inserisce l'indirizzo di ritorno nello stack: rsp = 992
add rax, 1      ; l'indirizzo di ritorno punta qui

ret inserisce quell'indirizzo in rip, il registro che contiene l'indirizzo della prossima istruzione. Il programma continua subito dopo call e rsp torna alla posizione in cui si trovava.

double:
    add rax, rax
    ret             ; preleva l'indirizzo di ritorno dallo stack: rsp = 1000

Prima di una chiamata, inserisci il valore dove la procedura se lo aspetta. Qui double raddoppia rax, quindi solve copia prima il suo input in rax:

solve:
    mov rax, rdi
    call double     ; rax = rdi * 2
    ret
double:
    add rax, rax
    ret

Anche solve è una procedura. Il file bloccato main.asm esegue call solve; il tuo ret vi ritorna e stampa rax, quindi ogni solve termina con ret.

challenge icon

Sfida

Facile

Scrivi una procedura double che raddoppi il valore in rax e lasci il risultato in rax. solve riceve un numero n (da -1000 a 1000) in rdi: copialo in rax, chiama double due volte e restituisci il risultato (4 volte n) in rax.

Esempio: per l'input 3, il programma stampa 12.

Scrivi il tuo codice in solution.asm. Il file bloccato main.asm legge l'input, chiama solve e stampa il numero in rax.

Provalo tu

bits 64
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall

Tutte le lezioni di Funzioni, stack e stringhe

Esercitati da solo: Playground Assembly