Ricorsione
Fa parte della sezione Funzioni, stack e stringhe del percorso Assembly di Coddy. Lezione 18 di 33.
Una funzione ricorsiva richiama sé stessa su una versione più semplice del problema. Il fattoriale di n è n moltiplicato per il fattoriale di n - 1: 4! = 4 * 3!. La catena si ferma a 1! = 1, e anche 0! = 1.
Ogni funzione ricorsiva ha bisogno di un caso base: un input a cui risponde senza richiamare sé stessa. Senza un caso base, le chiamate non si fermano mai. Ogni chiamata aggiunge un indirizzo di ritorno allo stack, e lo stack esaurisce lo spazio fino a quando il programma va in crash.
factorial riceve n in rdi e restituisce n! in rax:
factorial:
cmp rdi, 1
jg .recurse
mov eax, 1
ret
.recurse:
push rdi
dec rdi
call factorial
pop rdi
imul rax, rdi
retLa chiamata interna modifica rdi, quindi ogni chiamata inserisce il proprio n prima di chiamare e lo estrae dopo. Ogni chiamata ha il proprio indirizzo di ritorno e il proprio n salvato nello stack.
Per factorial(3): salva 3 e chiama factorial(2), che salva 2 e chiama factorial(1), che restituisce 1. I valori restituiti vengono poi elaborati in ordine inverso: 2 * 1 = 2, poi 3 * 2 = 6.
Sfida
FacileScrivi una funzione ricorsiva factorial: n in rdi (da 0 a 20), n! in rax, con 0! e 1! uguali a 1. solve riceve n in rdi, chiama factorial e restituisce il risultato in rax.
Esempio: per l'input 5 il programma stampa 120.
Scrivi il tuo codice in solution.asm. Il file bloccato main.asm legge l'input, chiama solve e stampa il numero in rax, oppure il nome di un registro preservato dal chiamato che solve ha modificato.
Provalo tu
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitTutte le lezioni di Funzioni, stack e stringhe
1Lo stack
PUSH e POPUltimo a entrare, primo a uscireSalvare un registroLeggere con [rsp]Riepilogo: cronologia degli annullamenti4Frame dello stack e ricorsione
Variabili localiFrame con RBPRicorsioneDue chiamate ricorsiveRiepilogo: somma delle cifre3La convenzione di chiamata
Argomenti nei registriValori di ritornoRegistri salvati dal chiamanteRegistri salvati dal chiamatoRiepilogo: tabellone dei punteggi6Progetto: Contatore di parole
La syscall di letturaConta i caratteriEsercitati da solo: Playground Assembly