Valori di ritorno
Fa parte della sezione Funzioni, stack e stringhe del percorso Assembly di Coddy. Lezione 12 di 33.
Una funzione restituisce il risultato in rax. Il chiamante legge rax subito dopo call, prima che qualcos'altro lo modifichi.
Scrivere una propria funzione segue le stesse regole: un'etichetta, codice che legge i suoi argomenti da rdi, rsi, rdx e lascia il risultato in rax, poi ret.
; sum3(rdi, rsi, rdx): restituisce rdi + rsi + rdx
sum3:
mov rax, rdi
add rax, rsi
add rax, rdx
retQuando solve riceve gli stessi argomenti che vuole passare, questi si trovano già nei registri giusti, quindi può chiamare subito la funzione e usare il risultato:
solve:
call sum3 ; rax = la somma dei tre input
imul rax, rax, 2
retUn'etichetta che inizia con un punto, come .done, appartiene all'ultima etichetta senza punto che la precede. Quindi due funzioni possono avere ciascuna il proprio .done; assegna a ogni funzione un'etichetta semplice come sum3.
rax è il registro del risultato, quindi una chiamata lo modifica sempre, anche se la funzione chiamata non restituisce nulla di utile. Non fare mai affidamento sul fatto che rax conservi un valore dopo una call: salvalo prima con push.
Sfida
FacileScrivi una funzione clamp: un valore in rdi, un limite inferiore in rsi e un limite superiore in rdx (tutti da -1000 a 1000, il limite inferiore non è mai superiore a quello superiore). Restituisce il valore in rax, portato al limite inferiore o ridotto al limite superiore se è al di fuori di questi limiti. solve riceve gli stessi tre numeri in rdi, rsi e rdx: chiama clamp e restituisce il suo risultato moltiplicato per 2 in rax.
Esempio: con l'input 5 1 10 il programma stampa 10.
Scrivi il tuo codice in solution.asm. Il file bloccato main.asm legge l'input, chiama solve e stampa il numero in rax, oppure il nome di un registro salvato dal chiamato che solve ha modificato.
Provalo tu
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitTutte le lezioni di Funzioni, stack e stringhe
1Lo stack
PUSH e POPUltimo a entrare, primo a uscireSalvare un registroLeggere con [rsp]Riepilogo: cronologia degli annullamenti4Frame dello stack e ricorsione
Variabili localiFrame con RBPRicorsioneDue chiamate ricorsiveRiepilogo: somma delle cifre3La convenzione di chiamata
Argomenti nei registriValori di ritornoRegistri salvati dal chiamanteRegistri salvati dal chiamatoRiepilogo: tabellone dei punteggi6Progetto: Contatore di parole
La syscall di letturaConta i caratteriEsercitati da solo: Playground Assembly