PUSH e POP
Fa parte della sezione Funzioni, stack e stringhe del percorso Assembly di Coddy. Lezione 1 di 33.
Lo stack è una regione di memoria che il programma usa per conservare valori per un breve periodo. Il registro rsp (il puntatore dello stack) contiene l’indirizzo del valore in cima allo stack. Quando il programma si avvia, rsp punta già allo stack.
push inserisce un valore di 8 byte in cima. push rdi sottrae prima 8 da rsp, poi memorizza rdi al nuovo indirizzo in rsp. Lo stack cresce verso il basso: ogni push sposta rsp a un indirizzo inferiore. Gli indirizzi reali sono numeri lunghi, quindi gli esempi ne usano di piccoli.
; rsp = 1000
push rdi ; rsp = 992, rdi è memorizzato a 992
push rsi ; rsp = 984, rsi è memorizzato a 984pop rimuove il valore in cima. pop rax copia gli 8 byte all'indirizzo contenuto in rsp in rax, poi aggiunge 8 a rsp.
; rsp = 984
pop rax ; rax = il valore da 984, rsp = 992
pop rbx ; rbx = il valore da 992, rsp = 1000Push e pop possono scambiare due registri senza usarne un terzo. Il primo pop restituisce l’ultimo valore inserito:
push rdi ; salva rdi
push rsi ; salva rsi in cima
pop rdi ; rdi = il precedente rsi
pop rsi ; rsi = il precedente rdiIn questa sezione, le sfide chiamano il tuo codice come un programma C chiama una funzione. Il file bloccato main.asm inserisce gli input in rdi, rsi, rdx e rcx, in quest'ordine, chiama la tua solve e stampa il numero che lasci in rax. Ogni attività specifica quali input usa. Il capitolo 3 spiega perché vengono usati questi registri.
Sfida
Facilesolve riceve due numeri: il primo in rdi, il secondo in rsi. Scambia i due registri con due istruzioni push e due pop, poi restituisci rdi - rsi in rax.
Esempio: per l'input 3 10, il programma stampa 7.
Scrivi il tuo codice in solution.asm. Il file bloccato main.asm legge l'input, chiama solve e stampa il numero in rax.
Provalo tu
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscallTutte le lezioni di Funzioni, stack e stringhe
1Lo stack
PUSH e POPUltimo a entrare, primo a uscireSalvare un registroLeggere con [rsp]Riepilogo: cronologia degli annullamenti4Frame dello stack e ricorsione
Variabili localiFrame con RBPRicorsioneDue chiamate ricorsiveRiepilogo: somma delle cifre3La convenzione di chiamata
Argomenti nei registriValori di ritornoRegistri salvati dal chiamanteRegistri salvati dal chiamatoRiepilogo: tabellone dei punteggi6Progetto: Contatore di parole
La syscall di letturaConta i caratteriEsercitati da solo: Playground Assembly