تعيد =AVERAGE(B2:B7) متوسط الأرقام في B2:B7: تجمعها وتقسم على عددها. اكتبها في خلية فارغة، أو اختر الصفحة الرئيسية > جمع تلقائي > المتوسط وسيكتبها الاكسل عنك.
| A | B | |
|---|---|---|
| 1 | Student | Score |
| 2 | Ana | 78 |
| 3 | Ben | 92 |
| 4 | Chen | 65 |
| 5 | Dina | 88 |
| 6 | Eli | 71 |
| 7 | Fay | 84 |
| 8 | Average | 79.66666667 |
مجموع الدرجات الست 478، و478 مقسومة على 6 تساوي نحو 79.67. غيّر درجة Chen إلى 95 فيرتفع المتوسط إلى 84.67. لعرض منازل عشرية أقل، استخدم الصفحة الرئيسية > إنقاص المنازل العشرية، أو قرّب النتيجة نفسها بالصيغة =ROUND(AVERAGE(B2:B7),1) (تشرح ROUND الفرق).
صيغة دالة AVERAGE
=AVERAGE(number1, [number2], ...)
مثل SUM، تقبل نطاقات وخلايا وأرقامًا تفصل بينها فواصل: تحسب =AVERAGE(B2:B7,D2:D7) متوسط عمودين معًا، وتحسب =AVERAGE(B2:D2) المتوسط عبر صف. تُتخطى النصوص وقيم TRUE/FALSE داخل النطاق والخلايا الفارغة.
الخلايا الفارغة مقابل الأصفار
من هنا تأتي معظم المتوسطات الخاطئة. تتخطى AVERAGE الخلية الفارغة، لكن 0 رقم ويُحسب. العمودان أدناه متطابقان إلا في Ben: في العمود B خليته فارغة، وفي العمود C تحتوي على 0.
| A | B | C | |
|---|---|---|---|
| 1 | Student | Blank | Zero |
| 2 | Ana | 80 | 80 |
| 3 | Ben | 0 | |
| 4 | Chen | 70 | 70 |
| 5 | Dina | 90 | 90 |
| 6 | Average | 80 | 60 |
| 7 | Numbers counted | 3 | 4 |
يعطي العمود B القيمة 80 (240 مقسومة على 3) ويعطي العمود C القيمة 60 (240 مقسومة على 4). لا أحدهما خاطئ؛ قرّر هل تعني القيمة المفقودة "لم يُجرَ الاختبار" أم "حصل على صفر". والصيغة التي تعيد "" لتبدو فارغة تُتخطى مثل الخلية الفارغة.
المتوسط دون أصفار
عندما تعني الأصفار "لا توجد بيانات" ولا ينبغي أن تخفض النتيجة، استخدم AVERAGEIF مع الشرط "<>0" (لا يساوي صفرًا):
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Day | Sales | Ignoring zeros | Plain average | |
| 2 | Mon | 420 | 440 | 293.3333333 | |
| 3 | Tue | 0 | |||
| 4 | Wed | 380 | |||
| 5 | Thu | 0 | |||
| 6 | Fri | 510 | |||
| 7 | Sat | 450 |
تعطي D2 القيمة 440، أي متوسط الأيام الأربعة التي فيها مبيعات. أما المتوسط العادي في E2 فنحو 293.33، لأنه يقسم على ستة أيام. ويستبعد "<>0" الخلايا الفارغة أيضًا، لأن AVERAGEIF لا تحسبها أبدًا. ستجد شروطًا أخرى في صفحة AVERAGEIF.
متوسط أعلى 3 قيم
تعيد LARGE القيمة الكبرى رقم k. أعطها المصفوفة {1,2,3} فتعيد أكبر ثلاث قيم دفعة واحدة، وتحسب AVERAGE متوسطها:
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Round | Points | Top 3 average | Bottom 3 average | |
| 2 | 1 | 64 | 85.33333333 | 64.66666667 | |
| 3 | 2 | 81 | |||
| 4 | 3 | 77 | |||
| 5 | 4 | 90 | |||
| 6 | 5 | 58 | |||
| 7 | 6 | 85 | |||
| 8 | 7 | 72 |
أعلى ثلاث قيم هي 90 و85 و81، لذا تعطي D2 القيمة 85.33 (مقربة). وأدنى ثلاث هي 58 و64 و72، فتعطي 64.67. في Excel 2021 وMicrosoft 365، تحسب =AVERAGE(LARGE(B2:B8,SEQUENCE(5))) متوسط أعلى 5 دون كتابة القائمة.
AVERAGEA: عندما يجب أن يُحسب النص صفرًا
تحسب AVERAGEA النص وFALSE كصفر وTRUE كواحد. مع الدرجتين 80 و70 والكلمة "absent" في B2:B4:
=AVERAGE(B2:B4) returns 75 (80 + 70, divided by 2)
=AVERAGEA(B2:B4) returns 50 (80 + 70 + 0, divided by 3)
استخدم AVERAGEA فقط عندما يعني الإدخال النصي صفرًا فعلًا. والخلايا الفارغة تتخطاها الدالتان كلتاهما.
تمرين: المتوسط دون الأصفار
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Day | Visits | Average (no zeros) | ||
| 2 | Mon | 120 | |||
| 3 | Tue | 0 | |||
| 4 | Wed | 135 | |||
| 5 | Thu | 98 | |||
| 6 | Fri | 0 | |||
| 7 | Sat | 160 | |||
| 8 | Sun | 142 |
دورك: في E2، احسب متوسط الزيارات في B2:B8 مستبعدًا الأيام التي فيها 0 زيارة.
عندما يضلل المتوسط: استخدم MEDIAN
قيمة متطرفة واحدة تحرك المتوسط كثيرًا. أما MEDIAN فتعيد القيمة الوسطى، وهي ما تعنيه عادة القيمة "النموذجية".
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Employee | Salary | Average | Median | |
| 2 | Ana | $42,000 | $78,800 | $47,000 | |
| 3 | Ben | $45,000 | |||
| 4 | Chen | $47,000 | |||
| 5 | Dina | $50,000 | |||
| 6 | Owner | $210,000 |
متوسط الراتب $78,800، وهو أكثر مما يكسبه أربعة من الأشخاص الخمسة. والوسيط $47,000. عندما تبتعد بعض القيم كثيرًا عن البقية، اذكر الوسيط، أو الاثنين معًا. ولإعطاء بعض القيم وزنًا أكبر من غيرها، مثل اختبار يُحسب مرتين، راجع المتوسط المرجح.
الأسئلة الشائعة
ما صيغة المتوسط في الاكسل؟
=AVERAGE(B2:B7). تجمع الأرقام في النطاق وتقسم على عددها. تُستبعد الخلايا الفارغة والنصوص من المجموع ومن العدد معًا.
هل تحسب AVERAGE الخلايا الفارغة في الاكسل؟
لا. تُتخطى الخلية الفارغة، لذا إذا كانت في =AVERAGE(B2:B5) خلية فارغة واحدة فإنها تقسم على 3. أما الخلية التي تحتوي على 0 فتُحسب، فتخفض المتوسط.
ما الفرق بين AVERAGE وMEDIAN في الاكسل؟
تجمع =AVERAGE(B2:B6) القيم وتقسم على عددها؛ وتعيد =MEDIAN(B2:B6) القيمة الوسطى بعد ترتيبها. قيمة متطرفة واحدة تحرك المتوسط لكنها لا تحرك الوسيط: للقيم 42000 و45000 و47000 و50000 و210000 يكون المتوسط 78800 والوسيط 47000.
كيف أحسب متوسط أعلى 3 قيم في الاكسل؟
تحسب =AVERAGE(LARGE(B2:B8,{1,2,3})) متوسط أكبر ثلاث قيم. ولأدنى 3، استخدم SMALL بدلًا من LARGE. ولأعلى 5 في Excel 2021 أو Microsoft 365: =AVERAGE(LARGE(B2:B8,SEQUENCE(5))).
لماذا تعيد AVERAGE الخطأ #DIV/0!؟
لأن النطاق لا يحتوي على أي أرقام: إما أنه فارغ، أو كل قيمه نصوص، مثل أرقام مخزنة كنص. عندها تقسم AVERAGE على صفر.
