تعدّ =NETWORKDAYS(A2,B2) أيام العمل من التاريخ في A2 إلى التاريخ في B2، مع التاريخين، ويوم العمل هو من الاثنين إلى الجمعة. وتسير =WORKDAY(A2,10) في الاتجاه المعاكس: تعيد التاريخ الذي يلي A2 بعشرة أيام عمل.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Start | End | Working days | Calendar days |
| 2 | 2026-03-02 | 2026-03-13 | 10 | 12 |
| 3 | 2026-03-02 | 2026-03-31 | 22 | 30 |
| 4 | 2026-03-06 | 2026-03-09 | 2 | 4 |
| 5 | 2026-03-07 | 2026-03-08 | 0 | 2 |
يمتد المشروع الأول من يوم اثنين إلى يوم جمعة من الأسبوع التالي: 12 يومًا تقويميًا، و10 أيام عمل. وفي شهر مارس 2026 كله ابتداءً من اليوم 2 هناك 22 يوم عمل. ومن الجمعة إلى الاثنين التالي 2، وعطلة نهاية الأسبوع وحدها 0. غيّر تاريخ نهاية لترى العدد يتغير. (لعدّ الأيام العادية راجع الأيام بين تاريخين.)
NETWORKDAYS مع العطلات
الوسيط الثالث نطاق من التواريخ يُتخطى إضافة إلى عطلات نهاية الأسبوع. احتفظ بالعطلات في عمود خاص بها (أو في ورقة أخرى) وثبّت النطاق بالرمز $ حتى يبقى في مكانه عند سحب الصيغة إلى الأسفل.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Start | End | No holidays | With holidays | Holidays |
| 2 | 2026-03-30 | 2026-04-10 | 10 | 8 | 2026-04-03 |
| 3 | 2026-04-01 | 2026-04-30 | 22 | 20 | 2026-04-06 |
| 4 | 2026-04-27 | 2026-05-08 | 10 | 9 | 2026-05-01 |
من 30 مارس إلى 10 أبريل عشرة أيام من أيام الأسبوع، منها يوما عطلة (الجمعة العظيمة واثنين الفصح في 2026)، فتكون 8 أيام عمل. ولا تُطرح إلا العطلات الواقعة داخل كل فترة: يخسر الصف الأخير 1 مايو ولا شيء غيره. احذف عطلة في العمود E فترتفع الأعداد من جديد.
WORKDAY: تاريخ استحقاق بأيام العمل
تعيد WORKDAY(start_date, days, [holidays]) التاريخ الذي يلي البداية بعدد من أيام العمل. لا يُحتسب تاريخ البداية نفسه، ولا تكون النتيجة أبدًا في عطلة نهاية الأسبوع أو في عطلة.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Received | Days | Due | Due (holidays) | Holidays |
| 2 | 2026-03-27 | 10 | 2026-04-10 | 2026-04-14 | 2026-04-03 |
| 3 | 2026-04-02 | 3 | 2026-04-07 | 2026-04-09 | 2026-04-06 |
| 4 | 2026-04-24 | 5 | 2026-05-01 | 2026-05-04 | 2026-05-01 |
الطلب الذي وصل يوم الجمعة 2026-03-27 مع 10 أيام عمل يستحق في 2026-04-10، أو في 2026-04-14 بعد تخطي الجمعة العظيمة واثنين الفصح. ومع عدد سالب من الأيام تعدّ WORKDAY إلى الوراء: =WORKDAY(A2,-5) هو يوم العمل قبل أسبوع. ولإيجاد "يوم العمل التالي" استخدم 1، وللإبقاء على تاريخ هو أصلًا يوم عمل، استخدم =WORKDAY(A2-1,1).
عطلات نهاية أسبوع أخرى: NETWORKDAYS.INTL
حيث لا تكون عطلة نهاية الأسبوع السبت والأحد، تأخذ NETWORKDAYS.INTL رمز عطلة نهاية الأسبوع وسيطًا ثالثًا والعطلات وسيطًا رابعًا.
| عطلة نهاية الأسبوع | الرمز |
|---|---|
| السبت والأحد | 1 (الافتراضي) |
| الأحد والاثنين | 2 |
| الجمعة والسبت | 7 |
| الأحد فقط | 11 |
| السبت فقط | 17 |
| أي نمط | 7 أحرف، تبدأ بالاثنين، 1 = يوم عطلة: "0000011" |
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Weekend | Code | Working days | Start | End | |
| 2 | Saturday and Sunday | 1 | 22 | 2026-03-01 | 2026-03-31 | |
| 3 | Friday and Saturday | 7 | 23 | |||
| 4 | Sunday only | 11 | 26 | |||
| 5 | Mon, Wed, Fri only | 0101011 | 13 |
في مارس 2026 هناك 22 يوم عمل مع عطلة السبت والأحد، و23 مع عطلة الجمعة والسبت، و26 عندما يكون الأحد وحده عطلة. والصف الأخير نمط عمل جزئي: يجعل 0101011 الثلاثاء والخميس عطلة إضافة إلى عطلة نهاية الأسبوع، فيبقى 13 يومًا. وفي الخلية، يجب أن يكون الرمز مثل 0101011 نصًا (اكتبه مع فاصلة علوية في أوله، '0101011)، وإلا يحذف الاكسل الصفر الأول.
وتفعل WORKDAY.INTL الشيء نفسه لتواريخ الاستحقاق. هذه نتائج الاكسل لعشرة أيام عمل بعد الاثنين 2 مارس 2026:
=WORKDAY.INTL(DATE(2026,3,2), 10) 2026-03-16 (Saturday and Sunday off)
=WORKDAY.INTL(DATE(2026,3,2), 10, 7) 2026-03-16 (Friday and Saturday off)
=WORKDAY.INTL(DATE(2026,3,2), 10, 11) 2026-03-13 (Sunday off)
=WORKDAY.INTL(DATE(2026,3,2), 10, "0000011") 2026-03-16 (same as code 1)
تمرين: أيام العمل وتاريخ الاستحقاق
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Start | End | Working days | Holidays | |
| 2 | 2026-04-01 | 2026-04-30 | 2026-04-03 | ||
| 3 | 2026-04-06 |
دورك: في C2، عدّ أيام العمل من A2 إلى B2، مع التاريخين، مع تخطي العطلات في E2:E3.
| A | B | C | |
|---|---|---|---|
| 1 | Received | Days | Due |
| 2 | 2026-05-14 | 8 |
دورك: في C2، أعد التاريخ الذي يلي التاريخ في A2 بعدد أيام العمل الموجود في B2 (مع تخطي عطلات نهاية الأسبوع، ودون عطلات).
تعدّ NETWORKDAYS الطرفين، ولا تعدّهما WORKDAY
تختلف الدالتان بيوم واحد بشأن تاريخ البداية، وهذا يفاجئ من يستخدمهما معًا. NETWORKDAYS من يوم اثنين إلى يوم جمعة من الأسبوع نفسه تساوي 5: يُحتسب اليومان. أما WORKDAY من ذلك الاثنين مع 5 أيام فتصل إلى الاثنين التالي، لأنها تبدأ العد من اليوم الذي يليه.
| A | B | C | |
|---|---|---|---|
| 1 | Start | WORKDAY(A2,5) | NETWORKDAYS back |
| 2 | 2026-03-02 | 2026-03-09 | 6 |
تعيد WORKDAY التاريخ 2026-03-09، وتعطي NETWORKDAYS من 2026-03-02 حتى ذلك التاريخ 6، لا 5. ولموعد نهائي "خلال 5 أيام عمل، مع احتساب اليوم"، استخدم =WORKDAY(A2,4) عندما تكون A2 يوم عمل. قرر مرة واحدة أي اصطلاح يستخدمه فريقك واكتبه بجانب الصيغة.
الأسئلة الشائعة
كيف أعدّ أيام العمل بين تاريخين في الاكسل؟
تعدّ =NETWORKDAYS(A2,B2) الأيام من الاثنين إلى الجمعة من A2 إلى B2، مع التاريخين. أضف نطاق تواريخ العطلات وسيطًا ثالثًا لتخطيها أيضًا: =NETWORKDAYS(A2,B2,$E$2:$E$4).
كيف أضيف أيام عمل إلى تاريخ في الاكسل؟
تعيد =WORKDAY(A2,10) التاريخ الذي يلي A2 بعشرة أيام عمل، متخطية أيام السبت والأحد. والعدد السالب يرجع إلى الوراء: =WORKDAY(A2,-5). أضف نطاق العطلات وسيطًا ثالثًا.
ما الفرق بين NETWORKDAYS وNETWORKDAYS.INTL؟
تعامل NETWORKDAYS السبت والأحد دائمًا على أنهما عطلة نهاية الأسبوع. وتأخذ NETWORKDAYS.INTL وسيطًا لعطلة نهاية الأسبوع: 7 للجمعة والسبت، و11 للأحد فقط، أو نصًا من سبعة أحرف مثل "0000011" حيث يمثل 1 يوم عطلة، بدءًا من الاثنين.
هل تحتسب NETWORKDAYS تاريخ البداية؟
نعم. تعدّ NETWORKDAYS تاريخ البداية وتاريخ النهاية كليهما عندما يكونان يومي عمل، لذا من الاثنين إلى الجمعة التالية 5. أما WORKDAY فلا تعدّ تاريخ البداية: =WORKDAY(A2,1) هو يوم العمل التالي.
ماذا يحدث إذا وقعت عطلة في نهاية الأسبوع؟
لا شيء إضافي: تتخطى NETWORKDAYS وWORKDAY أيام عطلة نهاية الأسبوع أصلًا، لذا لا تُطرح العطلة الواقعة يوم سبت مرتين.
